source: trunk/src/gui/gui.pro@ 853

Last change on this file since 853 was 853, checked in by Dmitry A. Kuminov, 14 years ago

gui: Fixed incorrect compiler calling when building mmx/sse helpers on OS/2.
File size: 9.7 KB
Line 
1TARGET = QtGui
2QPRO_PWD = $$PWD
3QT = core
4DEFINES += QT_BUILD_GUI_LIB QT_NO_USING_NAMESPACE
5win32-msvc*|win32-icc:QMAKE_LFLAGS += /BASE:0x65000000
6irix-cc*:QMAKE_CXXFLAGS += -no_prelink -ptused
7
8!win32:!embedded:!mac:!symbian:!os2:CONFIG += x11
9
10unix:QMAKE_PKGCONFIG_REQUIRES = QtCore
11
12include(../qbase.pri)
13
14contains(QT_CONFIG, x11sm):CONFIG += x11sm
15
16#platforms
17x11:include(kernel/x11.pri)
18mac:include(kernel/mac.pri)
19win32:include(kernel/win.pri)
20embedded:include(embedded/embedded.pri)
21symbian {
22 include(kernel/symbian.pri)
23 include(s60framework/s60framework.pri)
24}
25
26#modules
27include(animation/animation.pri)
28include(kernel/kernel.pri)
29include(image/image.pri)
30include(painting/painting.pri)
31include(text/text.pri)
32include(styles/styles.pri)
33include(widgets/widgets.pri)
34include(dialogs/dialogs.pri)
35include(accessible/accessible.pri)
36include(itemviews/itemviews.pri)
37include(inputmethod/inputmethod.pri)
38include(graphicsview/graphicsview.pri)
39include(util/util.pri)
40include(statemachine/statemachine.pri)
41include(math3d/math3d.pri)
42include(effects/effects.pri)
43
44include(egl/egl.pri)
45win32:!wince*: DEFINES += QT_NO_EGL
46embedded: QT += network
47
48QMAKE_LIBS += $$QMAKE_LIBS_GUI
49
50contains(DEFINES,QT_EVAL):include($$QT_SOURCE_TREE/src/corelib/eval.pri)
51
52QMAKE_DYNAMIC_LIST_FILE = $$PWD/QtGui.dynlist
53
54DEFINES += Q_INTERNAL_QAPP_SRC
55symbian {
56 TARGET.UID3=0x2001B2DD
57
58 symbian-abld|symbian-sbsv2 {
59 # ro-section in gui can exceed default allocated space, so move rw-section a little further
60 QMAKE_LFLAGS.ARMCC += --rw-base 0x800000
61 QMAKE_LFLAGS.GCCE += -Tdata 0xC00000
62 }
63}
64
65neon:*-g++* {
66 DEFINES += QT_HAVE_NEON
67 HEADERS += $$NEON_HEADERS
68 SOURCES += $$NEON_SOURCES
69
70 DRAWHELPER_NEON_ASM_FILES = $$NEON_ASM
71
72 neon_compiler.commands = $$QMAKE_CXX -c -mfpu=neon
73 neon_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
74 neon_compiler.dependency_type = TYPE_C
75 neon_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
76 neon_compiler.input = DRAWHELPER_NEON_ASM_FILES
77 neon_compiler.variable_out = OBJECTS
78 neon_compiler.name = compiling[neon] ${QMAKE_FILE_IN}
79 silent:neon_compiler.commands = @echo compiling[neon] ${QMAKE_FILE_IN} && $$neon_compiler.commands
80 QMAKE_EXTRA_COMPILERS += neon_compiler
81}
82
83contains(QMAKE_MAC_XARCH, no) {
84 DEFINES += QT_NO_MAC_XARCH
85} else {
86 win32-g++*|!win32:!win32-icc*:!macx-icc* {
87 mmx {
88 mmx_compiler.commands = $$QMAKE_CXX -c -Winline
89
90 mac {
91 mmx_compiler.commands += -Xarch_i386 -mmmx
92 mmx_compiler.commands += -Xarch_x86_64 -mmmx
93 } else {
94 mmx_compiler.commands += -mmmx
95 }
96
97 os2:mmx_compiler.commands += @$(CXXFLAGS_RSP) @$(INCPATH_RSP) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
98 else:mmx_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
99
100 mmx_compiler.dependency_type = TYPE_C
101 mmx_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
102 mmx_compiler.input = MMX_SOURCES
103 mmx_compiler.variable_out = OBJECTS
104 mmx_compiler.name = compiling[mmx] ${QMAKE_FILE_IN}
105 silent:mmx_compiler.commands = @echo compiling[mmx] ${QMAKE_FILE_IN} && $$mmx_compiler.commands
106 QMAKE_EXTRA_COMPILERS += mmx_compiler
107 }
108 3dnow {
109 mmx3dnow_compiler.commands = $$QMAKE_CXX -c -Winline
110
111 mac {
112 mmx3dnow_compiler.commands += -Xarch_i386 -m3dnow -Xarch_i386 -mmmx
113 mmx3dnow_compiler.commands += -Xarch_x86_64 -m3dnow -Xarch_x86_64 -mmmx
114 } else {
115 mmx3dnow_compiler.commands += -m3dnow -mmmx
116 }
117
118 os2:mmx3dnow_compiler.commands += @$(CXXFLAGS_RSP) @$(INCPATH_RSP) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
119 else:mmx3dnow_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
120
121 mmx3dnow_compiler.dependency_type = TYPE_C
122 mmx3dnow_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
123 mmx3dnow_compiler.input = MMX3DNOW_SOURCES
124 mmx3dnow_compiler.variable_out = OBJECTS
125 mmx3dnow_compiler.name = compiling[mmx3dnow] ${QMAKE_FILE_IN}
126 silent:mmx3dnow_compiler.commands = @echo compiling[mmx3dnow] ${QMAKE_FILE_IN} && $$mmx3dnow_compiler.commands
127 QMAKE_EXTRA_COMPILERS += mmx3dnow_compiler
128
129 sse {
130 sse3dnow_compiler.commands = $$QMAKE_CXX -c -Winline
131
132 mac {
133 sse3dnow_compiler.commands += -Xarch_i386 -m3dnow -Xarch_i386 -msse
134 sse3dnow_compiler.commands += -Xarch_x86_64 -m3dnow -Xarch_x86_64 -msse
135 } else {
136 sse3dnow_compiler.commands += -m3dnow -msse
137 }
138
139 os2:sse3dnow_compiler.commands += @$(CXXFLAGS_RSP) @$(INCPATH_RSP) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
140 else:sse3dnow_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
141
142 sse3dnow_compiler.dependency_type = TYPE_C
143 sse3dnow_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
144 sse3dnow_compiler.input = SSE3DNOW_SOURCES
145 sse3dnow_compiler.variable_out = OBJECTS
146 sse3dnow_compiler.name = compiling[sse3dnow] ${QMAKE_FILE_IN}
147 silent:sse3dnow_compiler.commands = @echo compiling[sse3dnow] ${QMAKE_FILE_IN} && $$sse3dnow_compiler.commands
148 QMAKE_EXTRA_COMPILERS += sse3dnow_compiler
149 }
150 }
151 sse {
152 sse_compiler.commands = $$QMAKE_CXX -c -Winline
153
154 mac {
155 sse_compiler.commands += -Xarch_i386 -msse
156 sse_compiler.commands += -Xarch_x86_64 -msse
157 } else {
158 sse_compiler.commands += -msse
159 }
160
161 os2:sse_compiler.commands += @$(CXXFLAGS_RSP) @$(INCPATH_RSP) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
162 else:sse_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
163
164 sse_compiler.dependency_type = TYPE_C
165 sse_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
166 sse_compiler.input = SSE_SOURCES
167 sse_compiler.variable_out = OBJECTS
168 sse_compiler.name = compiling[sse] ${QMAKE_FILE_IN}
169 silent:sse_compiler.commands = @echo compiling[sse] ${QMAKE_FILE_IN} && $$sse_compiler.commands
170 QMAKE_EXTRA_COMPILERS += sse_compiler
171 }
172 sse2 {
173 sse2_compiler.commands = $$QMAKE_CXX -c -Winline
174
175 mac {
176 sse2_compiler.commands += -Xarch_i386 -msse2
177 sse2_compiler.commands += -Xarch_x86_64 -msse2
178 } else {
179 sse2_compiler.commands += -msse2
180 }
181
182 os2:sse2_compiler.commands += @$(CXXFLAGS_RSP) @$(INCPATH_RSP) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
183 else:sse2_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
184
185 sse2_compiler.dependency_type = TYPE_C
186 sse2_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
187 sse2_compiler.input = SSE2_SOURCES
188 sse2_compiler.variable_out = OBJECTS
189 sse2_compiler.name = compiling[sse2] ${QMAKE_FILE_IN}
190 silent:sse2_compiler.commands = @echo compiling[sse2] ${QMAKE_FILE_IN} && $$sse2_compiler.commands
191 QMAKE_EXTRA_COMPILERS += sse2_compiler
192 }
193 ssse3 {
194 ssse3_compiler.commands = $$QMAKE_CXX -c -Winline
195
196 mac {
197 ssse3_compiler.commands += -Xarch_i386 -mssse3
198 ssse3_compiler.commands += -Xarch_x86_64 -mssse3
199 } else {
200 ssse3_compiler.commands += -mssse3
201 }
202
203 os2:ssse3_compiler.commands += @$(CXXFLAGS_RSP) @$(INCPATH_RSP) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
204 else:ssse3_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
205
206 ssse3_compiler.dependency_type = TYPE_C
207 ssse3_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
208 ssse3_compiler.input = SSSE3_SOURCES
209 ssse3_compiler.variable_out = OBJECTS
210 ssse3_compiler.name = compiling[ssse3] ${QMAKE_FILE_IN}
211 silent:ssse3_compiler.commands = @echo compiling[ssse3] ${QMAKE_FILE_IN} && $$ssse3_compiler.commands
212 QMAKE_EXTRA_COMPILERS += ssse3_compiler
213 }
214 iwmmxt {
215 iwmmxt_compiler.commands = $$QMAKE_CXX -c -Winline
216 iwmmxt_compiler.commands += -mcpu=iwmmxt
217
218 os2:iwmmxt_compiler.commands += @$(CXXFLAGS_RSP) @$(INCPATH_RSP) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
219 else:iwmmxt_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
220
221 iwmmxt_compiler.dependency_type = TYPE_C
222 iwmmxt_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
223 iwmmxt_compiler.input = IWMMXT_SOURCES
224 iwmmxt_compiler.variable_out = OBJECTS
225 iwmmxt_compiler.name = compiling[iwmmxt] ${QMAKE_FILE_IN}
226 silent:iwmmxt_compiler.commands = @echo compiling[iwmmxt] ${QMAKE_FILE_IN} && $$iwmmxt_compiler.commands
227 QMAKE_EXTRA_COMPILERS += iwmmxt_compiler
228 }
229 } else {
230 mmx: SOURCES += $$MMX_SOURCES
231 3dnow: SOURCES += $$MMX3DNOW_SOURCES
232 3dnow:sse: SOURCES += $$SSE3DNOW_SOURCES
233 sse: SOURCES += $$SSE_SOURCES
234 sse2: SOURCES += $$SSE2_SOURCES
235 ssse3: SOURCES += $$SSSE3_SOURCES
236 iwmmxt: SOURCES += $$IWMMXT_SOURCES
237 }
238}
Note: See TracBrowser for help on using the repository browser.