source: trunk/src/gui/gui.pro@ 855

Last change on this file since 855 was 855, checked in by Dmitry A. Kuminov, 14 years ago

gui: Improved r853 to make it actually biuld the mmx stuff.
File size: 9.8 KB
Line 
1TARGET = QtGui
2QPRO_PWD = $$PWD
3QT = core
4DEFINES += QT_BUILD_GUI_LIB QT_NO_USING_NAMESPACE
5win32-msvc*|win32-icc:QMAKE_LFLAGS += /BASE:0x65000000
6irix-cc*:QMAKE_CXXFLAGS += -no_prelink -ptused
7
8!win32:!embedded:!mac:!symbian:!os2:CONFIG += x11
9
10unix:QMAKE_PKGCONFIG_REQUIRES = QtCore
11
12include(../qbase.pri)
13
14contains(QT_CONFIG, x11sm):CONFIG += x11sm
15
16#platforms
17x11:include(kernel/x11.pri)
18mac:include(kernel/mac.pri)
19win32:include(kernel/win.pri)
20embedded:include(embedded/embedded.pri)
21symbian {
22 include(kernel/symbian.pri)
23 include(s60framework/s60framework.pri)
24}
25
26#modules
27include(animation/animation.pri)
28include(kernel/kernel.pri)
29include(image/image.pri)
30include(painting/painting.pri)
31include(text/text.pri)
32include(styles/styles.pri)
33include(widgets/widgets.pri)
34include(dialogs/dialogs.pri)
35include(accessible/accessible.pri)
36include(itemviews/itemviews.pri)
37include(inputmethod/inputmethod.pri)
38include(graphicsview/graphicsview.pri)
39include(util/util.pri)
40include(statemachine/statemachine.pri)
41include(math3d/math3d.pri)
42include(effects/effects.pri)
43
44include(egl/egl.pri)
45win32:!wince*: DEFINES += QT_NO_EGL
46embedded: QT += network
47
48QMAKE_LIBS += $$QMAKE_LIBS_GUI
49
50contains(DEFINES,QT_EVAL):include($$QT_SOURCE_TREE/src/corelib/eval.pri)
51
52QMAKE_DYNAMIC_LIST_FILE = $$PWD/QtGui.dynlist
53
54DEFINES += Q_INTERNAL_QAPP_SRC
55symbian {
56 TARGET.UID3=0x2001B2DD
57
58 symbian-abld|symbian-sbsv2 {
59 # ro-section in gui can exceed default allocated space, so move rw-section a little further
60 QMAKE_LFLAGS.ARMCC += --rw-base 0x800000
61 QMAKE_LFLAGS.GCCE += -Tdata 0xC00000
62 }
63}
64
65neon:*-g++* {
66 DEFINES += QT_HAVE_NEON
67 HEADERS += $$NEON_HEADERS
68 SOURCES += $$NEON_SOURCES
69
70 DRAWHELPER_NEON_ASM_FILES = $$NEON_ASM
71
72 neon_compiler.commands = $$QMAKE_CXX -c -mfpu=neon
73 neon_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
74 neon_compiler.dependency_type = TYPE_C
75 neon_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
76 neon_compiler.input = DRAWHELPER_NEON_ASM_FILES
77 neon_compiler.variable_out = OBJECTS
78 neon_compiler.name = compiling[neon] ${QMAKE_FILE_IN}
79 silent:neon_compiler.commands = @echo compiling[neon] ${QMAKE_FILE_IN} && $$neon_compiler.commands
80 QMAKE_EXTRA_COMPILERS += neon_compiler
81}
82
83contains(QMAKE_MAC_XARCH, no) {
84 DEFINES += QT_NO_MAC_XARCH
85} else {
86 win32-g++*|!win32:!win32-icc*:!macx-icc* {
87 os2 {
88 DRAWHELPER_OS2_COMPILER = $$QMAKE_RUN_CXX -Winline
89 DRAWHELPER_OS2_COMPILER = $$replace(DRAWHELPER_OS2_COMPILER, \\$src, ${QMAKE_FILE_IN})
90 DRAWHELPER_OS2_COMPILER = $$replace(DRAWHELPER_OS2_COMPILER, \\$obj, ${QMAKE_FILE_OUT})
91 }
92 mmx {
93 os2:mmx_compiler.commands = $$DRAWHELPER_OS2_COMPILER
94 else:mmx_compiler.commands = $$QMAKE_CXX -c -Winline
95
96 mac {
97 mmx_compiler.commands += -Xarch_i386 -mmmx
98 mmx_compiler.commands += -Xarch_x86_64 -mmmx
99 } else {
100 mmx_compiler.commands += -mmmx
101 }
102
103 !os2:mmx_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
104
105 mmx_compiler.dependency_type = TYPE_C
106 mmx_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
107 mmx_compiler.input = MMX_SOURCES
108 mmx_compiler.variable_out = OBJECTS
109 mmx_compiler.name = compiling[mmx] ${QMAKE_FILE_IN}
110 silent:mmx_compiler.commands = @echo compiling[mmx] ${QMAKE_FILE_IN} && $$mmx_compiler.commands
111 QMAKE_EXTRA_COMPILERS += mmx_compiler
112 }
113 3dnow {
114 os2:mmx3dnow_compiler.commands = $$DRAWHELPER_OS2_COMPILER
115 else:mmx3dnow_compiler.commands = $$QMAKE_CXX -c -Winline
116
117 mac {
118 mmx3dnow_compiler.commands += -Xarch_i386 -m3dnow -Xarch_i386 -mmmx
119 mmx3dnow_compiler.commands += -Xarch_x86_64 -m3dnow -Xarch_x86_64 -mmmx
120 } else {
121 mmx3dnow_compiler.commands += -m3dnow -mmmx
122 }
123
124 !os2:mmx3dnow_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
125
126 mmx3dnow_compiler.dependency_type = TYPE_C
127 mmx3dnow_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
128 mmx3dnow_compiler.input = MMX3DNOW_SOURCES
129 mmx3dnow_compiler.variable_out = OBJECTS
130 mmx3dnow_compiler.name = compiling[mmx3dnow] ${QMAKE_FILE_IN}
131 silent:mmx3dnow_compiler.commands = @echo compiling[mmx3dnow] ${QMAKE_FILE_IN} && $$mmx3dnow_compiler.commands
132 QMAKE_EXTRA_COMPILERS += mmx3dnow_compiler
133
134 sse {
135 os2:sse3dnow_compiler.commands = $$DRAWHELPER_OS2_COMPILER
136 else:sse3dnow_compiler.commands = $$QMAKE_CXX -c -Winline
137
138 mac {
139 sse3dnow_compiler.commands += -Xarch_i386 -m3dnow -Xarch_i386 -msse
140 sse3dnow_compiler.commands += -Xarch_x86_64 -m3dnow -Xarch_x86_64 -msse
141 } else {
142 sse3dnow_compiler.commands += -m3dnow -msse
143 }
144
145 !os2:sse3dnow_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
146
147 sse3dnow_compiler.dependency_type = TYPE_C
148 sse3dnow_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
149 sse3dnow_compiler.input = SSE3DNOW_SOURCES
150 sse3dnow_compiler.variable_out = OBJECTS
151 sse3dnow_compiler.name = compiling[sse3dnow] ${QMAKE_FILE_IN}
152 silent:sse3dnow_compiler.commands = @echo compiling[sse3dnow] ${QMAKE_FILE_IN} && $$sse3dnow_compiler.commands
153 QMAKE_EXTRA_COMPILERS += sse3dnow_compiler
154 }
155 }
156 sse {
157 os2:sse_compiler.commands = $$DRAWHELPER_OS2_COMPILER
158 else:sse_compiler.commands = $$QMAKE_CXX -c -Winline
159
160 mac {
161 sse_compiler.commands += -Xarch_i386 -msse
162 sse_compiler.commands += -Xarch_x86_64 -msse
163 } else {
164 sse_compiler.commands += -msse
165 }
166
167 !os2:sse_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
168
169 sse_compiler.dependency_type = TYPE_C
170 sse_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
171 sse_compiler.input = SSE_SOURCES
172 sse_compiler.variable_out = OBJECTS
173 sse_compiler.name = compiling[sse] ${QMAKE_FILE_IN}
174 silent:sse_compiler.commands = @echo compiling[sse] ${QMAKE_FILE_IN} && $$sse_compiler.commands
175 QMAKE_EXTRA_COMPILERS += sse_compiler
176 }
177 sse2 {
178 os2:sse2_compiler.commands = $$DRAWHELPER_OS2_COMPILER
179 else:sse2_compiler.commands = $$QMAKE_CXX -c -Winline
180
181 mac {
182 sse2_compiler.commands += -Xarch_i386 -msse2
183 sse2_compiler.commands += -Xarch_x86_64 -msse2
184 } else {
185 sse2_compiler.commands += -msse2
186 }
187
188 !os2:sse2_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
189
190 sse2_compiler.dependency_type = TYPE_C
191 sse2_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
192 sse2_compiler.input = SSE2_SOURCES
193 sse2_compiler.variable_out = OBJECTS
194 sse2_compiler.name = compiling[sse2] ${QMAKE_FILE_IN}
195 silent:sse2_compiler.commands = @echo compiling[sse2] ${QMAKE_FILE_IN} && $$sse2_compiler.commands
196 QMAKE_EXTRA_COMPILERS += sse2_compiler
197 }
198 ssse3 {
199 os2:ssse3_compiler.commands = $$DRAWHELPER_OS2_COMPILER
200 else:ssse3_compiler.commands = $$QMAKE_CXX -c -Winline
201
202 mac {
203 ssse3_compiler.commands += -Xarch_i386 -mssse3
204 ssse3_compiler.commands += -Xarch_x86_64 -mssse3
205 } else {
206 ssse3_compiler.commands += -mssse3
207 }
208
209 !os2:ssse3_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
210
211 ssse3_compiler.dependency_type = TYPE_C
212 ssse3_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
213 ssse3_compiler.input = SSSE3_SOURCES
214 ssse3_compiler.variable_out = OBJECTS
215 ssse3_compiler.name = compiling[ssse3] ${QMAKE_FILE_IN}
216 silent:ssse3_compiler.commands = @echo compiling[ssse3] ${QMAKE_FILE_IN} && $$ssse3_compiler.commands
217 QMAKE_EXTRA_COMPILERS += ssse3_compiler
218 }
219 iwmmxt {
220 os2:iwmmxt_compiler.commands = $$DRAWHELPER_OS2_COMPILER
221 else:iwmmxt_compiler.commands = $$QMAKE_CXX -c -Winline
222
223 iwmmxt_compiler.commands += -mcpu=iwmmxt
224
225 !os2:iwmmxt_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
226
227 iwmmxt_compiler.dependency_type = TYPE_C
228 iwmmxt_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
229 iwmmxt_compiler.input = IWMMXT_SOURCES
230 iwmmxt_compiler.variable_out = OBJECTS
231 iwmmxt_compiler.name = compiling[iwmmxt] ${QMAKE_FILE_IN}
232 silent:iwmmxt_compiler.commands = @echo compiling[iwmmxt] ${QMAKE_FILE_IN} && $$iwmmxt_compiler.commands
233 QMAKE_EXTRA_COMPILERS += iwmmxt_compiler
234 }
235 } else {
236 mmx: SOURCES += $$MMX_SOURCES
237 3dnow: SOURCES += $$MMX3DNOW_SOURCES
238 3dnow:sse: SOURCES += $$SSE3DNOW_SOURCES
239 sse: SOURCES += $$SSE_SOURCES
240 sse2: SOURCES += $$SSE2_SOURCES
241 ssse3: SOURCES += $$SSSE3_SOURCES
242 iwmmxt: SOURCES += $$IWMMXT_SOURCES
243 }
244}
Note: See TracBrowser for help on using the repository browser.