source: trunk/src/gui/gui.pro@ 846

Last change on this file since 846 was 846, checked in by Dmitry A. Kuminov, 14 years ago

trunk: Merged in qt 4.7.2 sources from branches/vendor/nokia/qt.
File size: 8.9 KB
Line 
1TARGET = QtGui
2QPRO_PWD = $$PWD
3QT = core
4DEFINES += QT_BUILD_GUI_LIB QT_NO_USING_NAMESPACE
5win32-msvc*|win32-icc:QMAKE_LFLAGS += /BASE:0x65000000
6irix-cc*:QMAKE_CXXFLAGS += -no_prelink -ptused
7
8!win32:!embedded:!mac:!symbian:!os2:CONFIG += x11
9
10unix:QMAKE_PKGCONFIG_REQUIRES = QtCore
11
12include(../qbase.pri)
13
14contains(QT_CONFIG, x11sm):CONFIG += x11sm
15
16#platforms
17x11:include(kernel/x11.pri)
18mac:include(kernel/mac.pri)
19win32:include(kernel/win.pri)
20embedded:include(embedded/embedded.pri)
21symbian {
22 include(kernel/symbian.pri)
23 include(s60framework/s60framework.pri)
24}
25
26#modules
27include(animation/animation.pri)
28include(kernel/kernel.pri)
29include(image/image.pri)
30include(painting/painting.pri)
31include(text/text.pri)
32include(styles/styles.pri)
33include(widgets/widgets.pri)
34include(dialogs/dialogs.pri)
35include(accessible/accessible.pri)
36include(itemviews/itemviews.pri)
37include(inputmethod/inputmethod.pri)
38include(graphicsview/graphicsview.pri)
39include(util/util.pri)
40include(statemachine/statemachine.pri)
41include(math3d/math3d.pri)
42include(effects/effects.pri)
43
44include(egl/egl.pri)
45win32:!wince*: DEFINES += QT_NO_EGL
46embedded: QT += network
47
48QMAKE_LIBS += $$QMAKE_LIBS_GUI
49
50contains(DEFINES,QT_EVAL):include($$QT_SOURCE_TREE/src/corelib/eval.pri)
51
52QMAKE_DYNAMIC_LIST_FILE = $$PWD/QtGui.dynlist
53
54DEFINES += Q_INTERNAL_QAPP_SRC
55symbian {
56 TARGET.UID3=0x2001B2DD
57
58 symbian-abld|symbian-sbsv2 {
59 # ro-section in gui can exceed default allocated space, so move rw-section a little further
60 QMAKE_LFLAGS.ARMCC += --rw-base 0x800000
61 QMAKE_LFLAGS.GCCE += -Tdata 0xC00000
62 }
63}
64
65neon:*-g++* {
66 DEFINES += QT_HAVE_NEON
67 HEADERS += $$NEON_HEADERS
68 SOURCES += $$NEON_SOURCES
69
70 DRAWHELPER_NEON_ASM_FILES = $$NEON_ASM
71
72 neon_compiler.commands = $$QMAKE_CXX -c -mfpu=neon
73 neon_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
74 neon_compiler.dependency_type = TYPE_C
75 neon_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
76 neon_compiler.input = DRAWHELPER_NEON_ASM_FILES
77 neon_compiler.variable_out = OBJECTS
78 neon_compiler.name = compiling[neon] ${QMAKE_FILE_IN}
79 silent:neon_compiler.commands = @echo compiling[neon] ${QMAKE_FILE_IN} && $$neon_compiler.commands
80 QMAKE_EXTRA_COMPILERS += neon_compiler
81}
82
83contains(QMAKE_MAC_XARCH, no) {
84 DEFINES += QT_NO_MAC_XARCH
85} else {
86 win32-g++*|!win32:!win32-icc*:!macx-icc* {
87 mmx {
88 mmx_compiler.commands = $$QMAKE_CXX -c -Winline
89
90 mac {
91 mmx_compiler.commands += -Xarch_i386 -mmmx
92 mmx_compiler.commands += -Xarch_x86_64 -mmmx
93 } else {
94 mmx_compiler.commands += -mmmx
95 }
96
97 mmx_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
98 mmx_compiler.dependency_type = TYPE_C
99 mmx_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
100 mmx_compiler.input = MMX_SOURCES
101 mmx_compiler.variable_out = OBJECTS
102 mmx_compiler.name = compiling[mmx] ${QMAKE_FILE_IN}
103 silent:mmx_compiler.commands = @echo compiling[mmx] ${QMAKE_FILE_IN} && $$mmx_compiler.commands
104 QMAKE_EXTRA_COMPILERS += mmx_compiler
105 }
106 3dnow {
107 mmx3dnow_compiler.commands = $$QMAKE_CXX -c -Winline
108
109 mac {
110 mmx3dnow_compiler.commands += -Xarch_i386 -m3dnow -Xarch_i386 -mmmx
111 mmx3dnow_compiler.commands += -Xarch_x86_64 -m3dnow -Xarch_x86_64 -mmmx
112 } else {
113 mmx3dnow_compiler.commands += -m3dnow -mmmx
114 }
115
116 mmx3dnow_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
117 mmx3dnow_compiler.dependency_type = TYPE_C
118 mmx3dnow_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
119 mmx3dnow_compiler.input = MMX3DNOW_SOURCES
120 mmx3dnow_compiler.variable_out = OBJECTS
121 mmx3dnow_compiler.name = compiling[mmx3dnow] ${QMAKE_FILE_IN}
122 silent:mmx3dnow_compiler.commands = @echo compiling[mmx3dnow] ${QMAKE_FILE_IN} && $$mmx3dnow_compiler.commands
123 QMAKE_EXTRA_COMPILERS += mmx3dnow_compiler
124 sse {
125 sse3dnow_compiler.commands = $$QMAKE_CXX -c -Winline
126
127 mac {
128 sse3dnow_compiler.commands += -Xarch_i386 -m3dnow -Xarch_i386 -msse
129 sse3dnow_compiler.commands += -Xarch_x86_64 -m3dnow -Xarch_x86_64 -msse
130 } else {
131 sse3dnow_compiler.commands += -m3dnow -msse
132 }
133
134 sse3dnow_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
135 sse3dnow_compiler.dependency_type = TYPE_C
136 sse3dnow_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
137 sse3dnow_compiler.input = SSE3DNOW_SOURCES
138 sse3dnow_compiler.variable_out = OBJECTS
139 sse3dnow_compiler.name = compiling[sse3dnow] ${QMAKE_FILE_IN}
140 silent:sse3dnow_compiler.commands = @echo compiling[sse3dnow] ${QMAKE_FILE_IN} && $$sse3dnow_compiler.commands
141 QMAKE_EXTRA_COMPILERS += sse3dnow_compiler
142 }
143 }
144 sse {
145 sse_compiler.commands = $$QMAKE_CXX -c -Winline
146
147 mac {
148 sse_compiler.commands += -Xarch_i386 -msse
149 sse_compiler.commands += -Xarch_x86_64 -msse
150 } else {
151 sse_compiler.commands += -msse
152 }
153
154 sse_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
155 sse_compiler.dependency_type = TYPE_C
156 sse_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
157 sse_compiler.input = SSE_SOURCES
158 sse_compiler.variable_out = OBJECTS
159 sse_compiler.name = compiling[sse] ${QMAKE_FILE_IN}
160 silent:sse_compiler.commands = @echo compiling[sse] ${QMAKE_FILE_IN} && $$sse_compiler.commands
161 QMAKE_EXTRA_COMPILERS += sse_compiler
162 }
163 sse2 {
164 sse2_compiler.commands = $$QMAKE_CXX -c -Winline
165
166 mac {
167 sse2_compiler.commands += -Xarch_i386 -msse2
168 sse2_compiler.commands += -Xarch_x86_64 -msse2
169 } else {
170 sse2_compiler.commands += -msse2
171 }
172
173 sse2_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
174 sse2_compiler.dependency_type = TYPE_C
175 sse2_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
176 sse2_compiler.input = SSE2_SOURCES
177 sse2_compiler.variable_out = OBJECTS
178 sse2_compiler.name = compiling[sse2] ${QMAKE_FILE_IN}
179 silent:sse2_compiler.commands = @echo compiling[sse2] ${QMAKE_FILE_IN} && $$sse2_compiler.commands
180 QMAKE_EXTRA_COMPILERS += sse2_compiler
181 }
182 ssse3 {
183 ssse3_compiler.commands = $$QMAKE_CXX -c -Winline
184
185 mac {
186 ssse3_compiler.commands += -Xarch_i386 -mssse3
187 ssse3_compiler.commands += -Xarch_x86_64 -mssse3
188 } else {
189 ssse3_compiler.commands += -mssse3
190 }
191
192 ssse3_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
193 ssse3_compiler.dependency_type = TYPE_C
194 ssse3_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
195 ssse3_compiler.input = SSSE3_SOURCES
196 ssse3_compiler.variable_out = OBJECTS
197 ssse3_compiler.name = compiling[ssse3] ${QMAKE_FILE_IN}
198 silent:ssse3_compiler.commands = @echo compiling[ssse3] ${QMAKE_FILE_IN} && $$ssse3_compiler.commands
199 QMAKE_EXTRA_COMPILERS += ssse3_compiler
200 }
201 iwmmxt {
202 iwmmxt_compiler.commands = $$QMAKE_CXX -c -Winline
203 iwmmxt_compiler.commands += -mcpu=iwmmxt
204 iwmmxt_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
205 iwmmxt_compiler.dependency_type = TYPE_C
206 iwmmxt_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
207 iwmmxt_compiler.input = IWMMXT_SOURCES
208 iwmmxt_compiler.variable_out = OBJECTS
209 iwmmxt_compiler.name = compiling[iwmmxt] ${QMAKE_FILE_IN}
210 silent:iwmmxt_compiler.commands = @echo compiling[iwmmxt] ${QMAKE_FILE_IN} && $$iwmmxt_compiler.commands
211 QMAKE_EXTRA_COMPILERS += iwmmxt_compiler
212 }
213 } else {
214 mmx: SOURCES += $$MMX_SOURCES
215 3dnow: SOURCES += $$MMX3DNOW_SOURCES
216 3dnow:sse: SOURCES += $$SSE3DNOW_SOURCES
217 sse: SOURCES += $$SSE_SOURCES
218 sse2: SOURCES += $$SSE2_SOURCES
219 ssse3: SOURCES += $$SSSE3_SOURCES
220 iwmmxt: SOURCES += $$IWMMXT_SOURCES
221 }
222}
Note: See TracBrowser for help on using the repository browser.