blob: b98ef039ff14365d076c265a37fb38d6a49f06c7 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit desktop qmake-utils
DESCRIPTION="Multi-platform GUI for pass, the standard unix password manager"
HOMEPAGE="https://qtpass.org https://github.com/IJHack/qtpass"
SRC_URI="https://github.com/IJHack/qtpass/archive/v${PV}.tar.gz -> ${P}.tar.gz"
S="${WORKDIR}/QtPass-${PV}"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~ppc64 ~x86"
IUSE="test"
RESTRICT="!test? ( test )"
RDEPEND="
|| (
app-admin/pass
app-admin/gopass
)
dev-qt/qtbase:6[gui,network,widgets]
net-misc/x11-ssh-askpass
"
DEPEND="${RDEPEND}
dev-qt/qtsvg:6
"
BDEPEND="dev-qt/qttools:6[linguist]"
DOCS=( {CHANGELOG,CONTRIBUTING,FAQ,README}.md )
PATCHES=(
"${FILESDIR}"/${P}-qt-6.8-buildfix.patch
"${FILESDIR}"/${P}-qt-6.8-profiles.patch
)
src_prepare() {
default
if ! use test ; then
sed -i '/SUBDIRS += src /s/tests //' \
qtpass.pro || die "sed for qtpass.pro failed"
fi
}
src_configure() {
eqmake6 PREFIX="${EPREFIX}"/usr
}
src_test() {
local -x QT_QPA_PLATFORM=offscreen
default
}
src_install() {
emake INSTALL_ROOT="${D}" install
einstalldocs
insinto /usr/share/qtpass/translations
doins src/.qm/*.qm
doman qtpass.1
domenu qtpass.desktop
newicon artwork/icon.png qtpass-icon.png
insinto /usr/share/metainfo
doins qtpass.appdata.xml
}
|
GitWeb
