| 1 | TARGET = QtGui
|
|---|
| 2 | QPRO_PWD = $$PWD
|
|---|
| 3 | QT = core
|
|---|
| 4 | DEFINES += QT_BUILD_GUI_LIB QT_NO_USING_NAMESPACE
|
|---|
| 5 | win32-msvc*|win32-icc:QMAKE_LFLAGS += /BASE:0x65000000
|
|---|
| 6 | irix-cc*:QMAKE_CXXFLAGS += -no_prelink -ptused
|
|---|
| 7 |
|
|---|
| 8 | !win32:!embedded:!mac:!symbian:!os2:CONFIG += x11
|
|---|
| 9 |
|
|---|
| 10 | unix:QMAKE_PKGCONFIG_REQUIRES = QtCore
|
|---|
| 11 |
|
|---|
| 12 | include(../qbase.pri)
|
|---|
| 13 |
|
|---|
| 14 | contains(QT_CONFIG, x11sm):CONFIG += x11sm
|
|---|
| 15 |
|
|---|
| 16 | #platforms
|
|---|
| 17 | x11:include(kernel/x11.pri)
|
|---|
| 18 | mac:include(kernel/mac.pri)
|
|---|
| 19 | win32:include(kernel/win.pri)
|
|---|
| 20 | embedded:include(embedded/embedded.pri)
|
|---|
| 21 | symbian {
|
|---|
| 22 | include(kernel/symbian.pri)
|
|---|
| 23 | include(s60framework/s60framework.pri)
|
|---|
| 24 | }
|
|---|
| 25 |
|
|---|
| 26 | #modules
|
|---|
| 27 | include(animation/animation.pri)
|
|---|
| 28 | include(kernel/kernel.pri)
|
|---|
| 29 | include(image/image.pri)
|
|---|
| 30 | include(painting/painting.pri)
|
|---|
| 31 | include(text/text.pri)
|
|---|
| 32 | include(styles/styles.pri)
|
|---|
| 33 | include(widgets/widgets.pri)
|
|---|
| 34 | include(dialogs/dialogs.pri)
|
|---|
| 35 | include(accessible/accessible.pri)
|
|---|
| 36 | include(itemviews/itemviews.pri)
|
|---|
| 37 | include(inputmethod/inputmethod.pri)
|
|---|
| 38 | include(graphicsview/graphicsview.pri)
|
|---|
| 39 | include(util/util.pri)
|
|---|
| 40 | include(statemachine/statemachine.pri)
|
|---|
| 41 | include(math3d/math3d.pri)
|
|---|
| 42 | include(effects/effects.pri)
|
|---|
| 43 |
|
|---|
| 44 | include(egl/egl.pri)
|
|---|
| 45 | win32:!wince*: DEFINES += QT_NO_EGL
|
|---|
| 46 | embedded: QT += network
|
|---|
| 47 |
|
|---|
| 48 | QMAKE_LIBS += $$QMAKE_LIBS_GUI
|
|---|
| 49 |
|
|---|
| 50 | contains(DEFINES,QT_EVAL):include($$QT_SOURCE_TREE/src/corelib/eval.pri)
|
|---|
| 51 |
|
|---|
| 52 | QMAKE_DYNAMIC_LIST_FILE = $$PWD/QtGui.dynlist
|
|---|
| 53 |
|
|---|
| 54 | DEFINES += Q_INTERNAL_QAPP_SRC
|
|---|
| 55 | symbian {
|
|---|
| 56 | TARGET.UID3=0x2001B2DD
|
|---|
| 57 |
|
|---|
| 58 | symbian-abld|symbian-sbsv2 {
|
|---|
| 59 | # ro-section in gui can exceed default allocated space, so move rw-section a little further
|
|---|
| 60 | QMAKE_LFLAGS.ARMCC += --rw-base 0x800000
|
|---|
| 61 | QMAKE_LFLAGS.GCCE += -Tdata 0xC00000
|
|---|
| 62 | }
|
|---|
| 63 | }
|
|---|
| 64 |
|
|---|
| 65 | neon:*-g++* {
|
|---|
| 66 | DEFINES += QT_HAVE_NEON
|
|---|
| 67 | HEADERS += $$NEON_HEADERS
|
|---|
| 68 | SOURCES += $$NEON_SOURCES
|
|---|
| 69 |
|
|---|
| 70 | DRAWHELPER_NEON_ASM_FILES = $$NEON_ASM
|
|---|
| 71 |
|
|---|
| 72 | neon_compiler.commands = $$QMAKE_CXX -c -mfpu=neon
|
|---|
| 73 | neon_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
|
|---|
| 74 | neon_compiler.dependency_type = TYPE_C
|
|---|
| 75 | neon_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
|
|---|
| 76 | neon_compiler.input = DRAWHELPER_NEON_ASM_FILES
|
|---|
| 77 | neon_compiler.variable_out = OBJECTS
|
|---|
| 78 | neon_compiler.name = compiling[neon] ${QMAKE_FILE_IN}
|
|---|
| 79 | silent:neon_compiler.commands = @echo compiling[neon] ${QMAKE_FILE_IN} && $$neon_compiler.commands
|
|---|
| 80 | QMAKE_EXTRA_COMPILERS += neon_compiler
|
|---|
|
|---|
