source: smplayer/trunk/src/smplayer.pro@ 188

Last change on this file since 188 was 188, checked in by Silvan Scherrer, 9 years ago

SMPlayer: update trunk to version 17.1.0
  • Property svn:eol-style set to LF
File size: 16.1 KB
Line 
1TEMPLATE = app
2LANGUAGE = C++
3
4CONFIG += qt warn_on
5CONFIG += release
6#CONFIG += debug
7
8QT += network xml
9
10RESOURCES = icons.qrc
11
12#DEFINES += EXPERIMENTAL
13DEFINES += SINGLE_INSTANCE
14DEFINES += FIND_SUBTITLES
15DEFINES += VIDEOPREVIEW
16DEFINES += YOUTUBE_SUPPORT
17DEFINES += BLURAY_SUPPORT
18DEFINES += TV_SUPPORT
19DEFINES += GUI_CHANGE_ON_RUNTIME
20DEFINES += LOG_MPLAYER
21DEFINES += LOG_SMPLAYER
22DEFINES += DEFAULTGUI
23DEFINES += MINIGUI
24DEFINES += MPCGUI
25DEFINES += SKINS
26!os2 {
27DEFINES += MPRIS2
28}
29DEFINES += UPDATE_CHECKER
30DEFINES += CHECK_UPGRADED
31!os2 {
32DEFINES += AUTO_SHUTDOWN_PC
33}
34DEFINES += CAPTURE_STREAM
35DEFINES += BOOKMARKS
36DEFINES += MOUSE_GESTURES
37DEFINES += GLOBALSHORTCUTS
38DEFINES += ADD_BLACKBORDERS_FS
39DEFINES += INITIAL_BLACKBORDERS
40DEFINES += CHROMECAST_SUPPORT
41
42!os2 {
43DEFINES += MPV_SUPPORT
44}
45DEFINES += MPLAYER_SUPPORT
46
47# Whether to include support for the obsolete mplayer2 or not
48# (requires MPLAYER_SUPPORT)
49DEFINES += MPLAYER2_SUPPORT
50
51# Note to distro maintainers:
52# By disabling SHARE_ACTIONS or SHARE_WIDGET
53# you're preventing SMPlayer to receive donations and thus
54# SERIOUSLY HURTING THE DEVELOPMENT AND PUTTING
55# AT RISK THE CONTINUATION OF THIS PROJECT
56# Please don't.
57
58#DEFINES += SHARE_ACTIONS
59#DEFINES += SHARE_WIDGET
60
61# If Qt >= 5.4
62greaterThan(QT_MAJOR_VERSION, 4):greaterThan(QT_MINOR_VERSION, 3) {
63 DEFINES += HDPI_SUPPORT
64}
65
66#DEFINES += SIMPLE_BUILD
67#DEFINES += IDOPT_BUILD
68
69contains( DEFINES, SIMPLE_BUILD ) {
70 DEFINES -= SINGLE_INSTANCE
71 DEFINES -= FIND_SUBTITLES
72 DEFINES -= VIDEOPREVIEW
73 DEFINES -= LOG_MPLAYER
74 DEFINES -= LOG_SMPLAYER
75 DEFINES -= MINIGUI
76 DEFINES -= MPCGUI
77 DEFINES -= SKINS
78 DEFINES -= MPRIS2
79 DEFINES -= UPDATE_CHECKER
80 DEFINES -= CHECK_UPGRADED
81 DEFINES -= SHARE_ACTIONS
82 DEFINES -= SHARE_WIDGET
83 DEFINES -= AUTO_SHUTDOWN_PC
84 DEFINES -= BOOKMARKS
85 DEFINES -= TV_SUPPORT
86 DEFINES -= CHROMECAST_SUPPORT
87}
88
89contains( DEFINES, IDOPT_BUILD ) {
90 DEFINES -= MPCGUI
91 DEFINES -= SKINS
92 DEFINES -= CAPTURE_STREAM
93 DEFINES -= TV_SUPPORT
94 DEFINES -= MPLAYER_SUPPORT
95 DEFINES -= MPLAYER2_SUPPORT
96}
97
98isEqual(QT_MAJOR_VERSION, 5) {
99 QT += widgets gui
100 #DEFINES += QT_DISABLE_DEPRECATED_BEFORE=0x040000
101 win32 {
102 DEFINES -= MPRIS2
103 }
104}
105
106contains(QT_VERSION, ^4\\.[0-3]\\..*) {
107 message("Some features requires Qt > 4.3.")
108
109 contains( DEFINES, SINGLE_INSTANCE ) {
110 DEFINES -= SINGLE_INSTANCE
111 message("SINGLE_INSTANCE disabled.")
112 }
113
114 contains( DEFINES, YOUTUBE_SUPPORT ) {
115 DEFINES -= YOUTUBE_SUPPORT
116 message("YOUTUBE_SUPPORT disabled.")
117 }
118
119 contains( DEFINES, SKINS ) {
120 DEFINES -= SKINS
121 message("SKINS disabled.")
122 }
123
124 contains( DEFINES, FIND_SUBTITLES ) {
125 DEFINES -= FIND_SUBTITLES
126 message("FIND_SUBTITLES disabled.")
127 }
128
129 contains( DEFINES, UPDATE_CHECKER ) {
130 DEFINES -= UPDATE_CHECKER
131 message("UPDATE_CHECKER disabled.")
132 }
133}
134
135contains( DEFINES, GLOBALSHORTCUTS ) {
136 lessThan(QT_MAJOR_VERSION, 5) {
137 DEFINES -= GLOBALSHORTCUTS
138 message("GLOBALSHORTCUTS requires Qt 5. Disabled.")
139 }
140}
141
142HEADERS += guiconfig.h \
143 config.h \
144 constants.h \
145 links.h \
146 svn_revision.h \
147 version.h \
148 chapters.h \
149 global.h \
150 paths.h \
151 helper.h \
152 colorutils.h \
153 translator.h \
154 subtracks.h \
155 tracks.h \
156 titletracks.h \
157 discname.h \
158 extensions.h \
159 desktopinfo.h \
160 myprocess.h \
161 mplayerversion.h \
162 playerid.h \
163 playerprocess.h \
164 infoprovider.h \
165 mplayerwindow.h \
166 mediadata.h \
167 audioequalizerlist.h \
168 mediasettings.h \
169 assstyles.h \
170 filters.h \
171 preferences.h \
172 filesettingsbase.h \
173 filesettings.h \
174 filesettingshash.h \
175 filehash.h \
176 images.h \
177 inforeader.h \
178 deviceinfo.h \
179 recents.h \
180 urlhistory.h \
181 core.h \
182 myscroller.h \
183 logwindow.h \
184 infowindow.h \
185 infofile.h \
186 seekwidget.h \
187 mytablewidget.h \
188 shortcutgetter.h \
189 actionseditor.h \
190 filechooser.h \
191 vdpauproperties.h \
192 preferencesdialog.h \
193 lineedit_with_icon.h \
194 mylineedit.h \
195 mycombobox.h \
196 tristatecombo.h \
197 languages.h \
198 selectcolorbutton.h \
199 prefwidget.h \
200 prefgeneral.h \
201 prefdrives.h \
202 prefinterface.h \
203 prefperformance.h \
204 prefinput.h \
205 prefsubtitles.h \
206 prefadvanced.h \
207 prefplaylist.h \
208 prefupdates.h \
209 prefnetwork.h \
210 filepropertiesdialog.h \
211 multilineinputdialog.h \
212 playlist.h \
213 playlistdock.h \
214 verticaltext.h \
215 eqslider.h \
216 videoequalizer.h \
217 audioequalizer.h \
218 myslider.h \
219 timeslider.h \
220 inputdvddirectory.h \
221 inputurl.h \
222 stereo3ddialog.h \
223 myaction.h \
224 myactiongroup.h \
225 filedialog.h \
226 inputmplayerversion.h \
227 about.h \
228 errordialog.h \
229 timedialog.h \
230 favorites.h \
231 favoriteeditor.h \
232 statewidget.h \
233 basegui.h \
234 baseguiplus.h \
235 autohidewidget.h \
236 widgetactions.h \
237 toolbareditor.h \
238 editabletoolbar.h \
239 clhelp.h \
240 cleanconfig.h \
241 smplayer.h \
242 myapplication.h
243
244
245SOURCES += version.cpp \
246 global.cpp \
247 paths.cpp \
248 chapters.cpp \
249 helper.cpp \
250 colorutils.cpp \
251 translator.cpp \
252 subtracks.cpp \
253 tracks.cpp \
254 titletracks.cpp \
255 discname.cpp \
256 extensions.cpp \
257 desktopinfo.cpp \
258 myprocess.cpp \
259 mplayerversion.cpp \
260 playerid.cpp \
261 playerprocess.cpp \
262 infoprovider.cpp \
263 mplayerwindow.cpp \
264 mediadata.cpp \
265 mediasettings.cpp \
266 assstyles.cpp \
267 filters.cpp \
268 preferences.cpp \
269 filesettingsbase.cpp \
270 filesettings.cpp \
271 filesettingshash.cpp \
272 filehash.cpp \
273 images.cpp \
274 inforeader.cpp \
275 deviceinfo.cpp \
276 recents.cpp \
277 urlhistory.cpp \
278 core.cpp \
279 myscroller.cpp \
280 logwindow.cpp \
281 infowindow.cpp \
282 infofile.cpp \
283 seekwidget.cpp \
284 mytablewidget.cpp \
285 shortcutgetter.cpp \
286 actionseditor.cpp \
287 filechooser.cpp \
288 vdpauproperties.cpp \
289 preferencesdialog.cpp \
290 lineedit_with_icon.cpp \
291 mylineedit.cpp \
292 mycombobox.cpp \
293 tristatecombo.cpp \
294 languages.cpp \
295 selectcolorbutton.cpp \
296 prefwidget.cpp \
297 prefgeneral.cpp \
298 prefdrives.cpp \
299 prefinterface.cpp \
300 prefperformance.cpp \
301 prefinput.cpp \
302 prefsubtitles.cpp \
303 prefadvanced.cpp \
304 prefplaylist.cpp \
305 prefupdates.cpp \
306 prefnetwork.cpp \
307 filepropertiesdialog.cpp \
308 multilineinputdialog.cpp \
309 playlist.cpp \
310 playlistdock.cpp \
311 verticaltext.cpp \
312 eqslider.cpp \
313 videoequalizer.cpp \
314 audioequalizer.cpp \
315 myslider.cpp \
316 timeslider.cpp \
317 inputdvddirectory.cpp \
318 inputurl.cpp \
319 stereo3ddialog.cpp \
320 myaction.cpp \
321 myactiongroup.cpp \
322 filedialog.cpp \
323 inputmplayerversion.cpp \
324 about.cpp \
325 errordialog.cpp \
326 timedialog.cpp \
327 favorites.cpp \
328 favoriteeditor.cpp \
329 statewidget.cpp \
330 basegui.cpp \
331 baseguiplus.cpp \
332 autohidewidget.cpp \
333 widgetactions.cpp \
334 toolbareditor.cpp \
335 editabletoolbar.cpp \
336 clhelp.cpp \
337 cleanconfig.cpp \
338 smplayer.cpp \
339 myapplication.cpp \
340 main.cpp
341
342FORMS = inputdvddirectory.ui logwindow.ui infowindow.ui filepropertiesdialog.ui \
343 eqslider.ui seekwidget.ui inputurl.ui videoequalizer.ui vdpauproperties.ui \
344 preferencesdialog.ui prefgeneral.ui prefdrives.ui prefinterface.ui \
345 prefperformance.ui prefinput.ui prefsubtitles.ui prefadvanced.ui \
346 prefplaylist.ui prefupdates.ui prefnetwork.ui favoriteeditor.ui \
347 about.ui inputmplayerversion.ui errordialog.ui timedialog.ui stereo3ddialog.ui \
348 toolbareditor.ui multilineinputdialog.ui
349
350contains( DEFINES, TV_SUPPORT ) {
351 HEADERS += tvlist.h preftv.h tvsettings.h
352 SOURCES += tvlist.cpp preftv.cpp tvsettings.cpp
353 FORMS += preftv.ui
354}
355
356contains( DEFINES, MPV_SUPPORT ) {
357 HEADERS += mpvprocess.h inforeadermpv.h
358 SOURCES += mpvprocess.cpp inforeadermpv.cpp
359}
360
361contains( DEFINES, MPLAYER_SUPPORT ) {
362 HEADERS += mplayerprocess.h inforeadermplayer.h
363 SOURCES += mplayerprocess.cpp inforeadermplayer.cpp
364}
365
366# qtsingleapplication
367contains( DEFINES, SINGLE_INSTANCE ) {
368 INCLUDEPATH += qtsingleapplication
369 DEPENDPATH += qtsingleapplication
370
371 SOURCES += qtsingleapplication/qtsingleapplication.cpp qtsingleapplication/qtlocalpeer.cpp
372 HEADERS += qtsingleapplication/qtsingleapplication.h qtsingleapplication/qtlocalpeer.h
373}
374
375# Find subtitles dialog
376contains( DEFINES, FIND_SUBTITLES ) {
377 DEFINES += DOWNLOAD_SUBS
378 DEFINES += OS_SEARCH_WORKAROUND
379 #DEFINES += USE_QUAZIP
380
381 INCLUDEPATH += findsubtitles
382 DEPENDPATH += findsubtitles
383
384 INCLUDEPATH += findsubtitles/maia
385 DEPENDPATH += findsubtitles/maia
386
387 HEADERS += findsubtitles/findsubtitlesconfigdialog.h findsubtitles/findsubtitleswindow.h
388 SOURCES += findsubtitles/findsubtitlesconfigdialog.cpp findsubtitles/findsubtitleswindow.cpp
389 FORMS += findsubtitles/findsubtitleswindow.ui findsubtitles/findsubtitlesconfigdialog.ui
390
391 # xmlrpc client code to connect to opensubtitles.org
392 HEADERS += findsubtitles/maia/maiaObject.h findsubtitles/maia/maiaFault.h findsubtitles/maia/maiaXmlRpcClient.h findsubtitles/osclient.h
393 SOURCES += findsubtitles/maia/maiaObject.cpp findsubtitles/maia/maiaFault.cpp findsubtitles/maia/maiaXmlRpcClient.cpp findsubtitles/osclient.cpp
394}
395
396# Download subtitles
397contains( DEFINES, DOWNLOAD_SUBS ) {
398 INCLUDEPATH += findsubtitles/filedownloader
399 DEPENDPATH += findsubtitles/filedownloader
400
401 HEADERS += findsubtitles/filedownloader/filedownloader.h findsubtitles/subchooserdialog.h findsubtitles/fixsubs.h
402 SOURCES += findsubtitles/filedownloader/filedownloader.cpp findsubtitles/subchooserdialog.cpp findsubtitles/fixsubs.cpp
403
404 FORMS += findsubtitles/subchooserdialog.ui
405
406 contains( DEFINES, USE_QUAZIP ) {
407 INCLUDEPATH += findsubtitles/quazip
408 DEPENDPATH += findsubtitles/quazip
409
410 HEADERS += crypt.h \
411 ioapi.h \
412 quazip.h \
413 quazipfile.h \
414 quazipfileinfo.h \
415 quazipnewinfo.h \
416 unzip.h \
417 zip.h
418
419 SOURCES += ioapi.c \
420 quazip.cpp \
421 quazipfile.cpp \
422 quazipnewinfo.cpp \
423 unzip.c \
424 zip.c
425}
426
427 LIBS += -lz
428
429 win32 {
430 INCLUDEPATH += ..\\zlib
431 LIBS += -L..\\zlib
432 }
433}
434
435# Youtube support
436contains( DEFINES, YOUTUBE_SUPPORT ) {
437 DEFINES += YT_USE_SCRIPT
438 INCLUDEPATH += youtube
439 DEPENDPATH += youtube
440
441 HEADERS += youtube/retrieveyoutubeurl.h youtube/loadpage.h
442 SOURCES += youtube/retrieveyoutubeurl.cpp youtube/loadpage.cpp
443
444 contains( DEFINES, YT_USE_SCRIPT ) {
445 DEFINES += YT_USE_SIG
446 DEFINES += YT_USE_YTSIG
447 QT += script
448 }
449
450 contains( DEFINES, YT_USE_SIG ) {
451 HEADERS += youtube/sig.h
452 SOURCES += youtube/sig.cpp
453 }
454
455 contains( DEFINES, YT_USE_YTSIG ) {
456 HEADERS += youtube/ytsig.h youtube/codedownloader.h
457 SOURCES += youtube/ytsig.cpp youtube/codedownloader.cpp
458 }
459}
460
461# defaultgui
462contains( DEFINES, DEFAULTGUI ) {
463 HEADERS += defaultgui.h
464 SOURCES += defaultgui.cpp
465}
466
467# minigui
468contains( DEFINES, MINIGUI ) {
469 HEADERS += minigui.h
470 SOURCES += minigui.cpp
471}
472
473# mpcgui
474contains( DEFINES, MPCGUI ) {
475 INCLUDEPATH += mpcgui
476 DEPENDPATH += mpcgui
477
478 HEADERS += mpcgui/mpcgui.h mpcgui/mpcstyles.h
479 SOURCES += mpcgui/mpcgui.cpp mpcgui/mpcstyles.cpp
480}
481
482# Skins support
483contains( DEFINES, SKINS ) {
484 INCLUDEPATH += skingui
485 DEPENDPATH += skingui
486
487 HEADERS += skingui/myicon.h skingui/mybutton.h skingui/panelseeker.h skingui/playcontrol.h \
488 skingui/mediapanel.h skingui/volumecontrolpanel.h skingui/mediabarpanel.h \
489 skingui/qpropertysetter.h skingui/actiontools.h skingui/skingui.h
490 SOURCES += skingui/myicon.cpp skingui/mybutton.cpp skingui/panelseeker.cpp skingui/playcontrol.cpp \
491 skingui/mediapanel.cpp skingui/volumecontrolpanel.cpp skingui/mediabarpanel.cpp \
492 skingui/qpropertysetter.cpp skingui/actiontools.cpp skingui/skingui.cpp
493 FORMS += skingui/mediapanel.ui skingui/mediabarpanel.ui
494}
495
496contains( DEFINES, MPRIS2 ) {
497 INCLUDEPATH += mpris2
498 DEPENDPATH += mpris2
499
500 HEADERS += mpris2/mediaplayer2.h mpris2/mediaplayer2player.h mpris2/mpris2.h
501 SOURCES += mpris2/mediaplayer2.cpp mpris2/mediaplayer2player.cpp mpris2/mpris2.cpp
502
503 QT += dbus
504}
505
506# Update checker
507contains( DEFINES, UPDATE_CHECKER ) {
508 HEADERS += updatechecker.h updatecheckerdata.h
509 SOURCES += updatechecker.cpp updatecheckerdata.cpp
510}
511
512# Videopreview
513contains( DEFINES, VIDEOPREVIEW ) {
514 INCLUDEPATH += videopreview
515 DEPENDPATH += videopreview
516
517 HEADERS += videopreview/videopreview.h videopreview/videopreviewconfigdialog.h
518 SOURCES += videopreview/videopreview.cpp videopreview/videopreviewconfigdialog.cpp
519
520 FORMS += videopreview/videopreviewconfigdialog.ui
521}
522
523
524contains( DEFINES, SHARE_ACTIONS ) {
525 HEADERS += sharedialog.h
526 SOURCES += sharedialog.cpp
527 FORMS += sharedialog.ui
528}
529
530contains( DEFINES, SHARE_WIDGET|SHARE_ACTIONS ) {
531 HEADERS += sharewidget.h sharedata.h
532 SOURCES += sharewidget.cpp sharedata.cpp
533}
534
535contains( DEFINES, AUTO_SHUTDOWN_PC ) {
536 HEADERS += shutdowndialog.h shutdown.h
537 SOURCES += shutdowndialog.cpp shutdown.cpp
538 FORMS += shutdowndialog.ui
539
540 unix { QT += dbus }
541}
542
543contains( DEFINES, BOOKMARKS ) {
544 HEADERS += inputbookmark.h bookmarkdialog.h
545 SOURCES += inputbookmark.cpp bookmarkdialog.cpp
546 FORMS += inputbookmark.ui bookmarkdialog.ui
547}
548
549contains( DEFINES, GLOBALSHORTCUTS ) {
550 HEADERS += globalshortcuts/globalshortcuts.h
551 SOURCES += globalshortcuts/globalshortcuts.cpp
552 unix {
553 QT += gui-private
554 LIBS += $${QMAKE_LIBS_X11}
555 }
556}
557
558contains( DEFINES, HDPI_SUPPORT ) {
559 HEADERS += hdpisupport.h
560 SOURCES += hdpisupport.cpp
561}
562
563contains( DEFINES, CHROMECAST_SUPPORT ) {
564 HEADERS += chromecast.h
565 SOURCES += chromecast.cpp
566}
567
568unix {
569 UI_DIR = .ui
570 MOC_DIR = .moc
571 OBJECTS_DIR = .obj
572
573 DEFINES += DATA_PATH=$(DATA_PATH)
574 DEFINES += DOC_PATH=$(DOC_PATH)
575 DEFINES += TRANSLATION_PATH=$(TRANSLATION_PATH)
576 DEFINES += THEMES_PATH=$(THEMES_PATH)
577 DEFINES += SHORTCUTS_PATH=$(SHORTCUTS_PATH)
578 #DEFINES += NO_DEBUG_ON_CONSOLE
579
580 ### PulseAudio
581 #CONFIG += link_pkgconfig
582 #PKGCONFIG += libpulse-mainloop-glib
583}
584
585win32 {
586 DEFINES += SCREENSAVER_OFF
587 DEFINES += AVOID_SCREENSAVER
588 #DEFINES += FONTCACHE_DIALOG
589 #DEFINES += FONTS_HACK
590
591 contains( DEFINES, SCREENSAVER_OFF ) {
592 HEADERS += screensaver.h
593 SOURCES += screensaver.cpp
594 }
595
596 contains( DEFINES, FONTCACHE_DIALOG ) {
597 HEADERS += fontcache.h
598 SOURCES += fontcache.cpp
599 }
600
601 !contains( DEFINES, PORTABLE_APP ) {
602 DEFINES += USE_ASSOCIATIONS
603 } else {
604 DEFINES -= HDPI_SUPPORT
605 }
606
607 contains( DEFINES, USE_ASSOCIATIONS ) {
608 HEADERS += prefassociations.h winfileassoc.h
609 SOURCES += prefassociations.cpp winfileassoc.cpp
610 FORMS += prefassociations.ui
611 }
612
613 contains(TEMPLATE,vcapp) {
614 LIBS += ole32.lib user32.lib
615 } else {
616 LIBS += libole32
617 }
618
619 LIBS += -ldsound -lddraw
620
621 RC_FILE = smplayer.rc
622 DEFINES += NO_DEBUG_ON_CONSOLE
623 #debug {
624 # CONFIG += console
625 #}
626}
627
628os2 {
629 DEFINES += SCREENSAVER_OFF
630 DEFINES += AVOID_SCREENSAVER
631 INCLUDEPATH += .
632 contains( DEFINES, SCREENSAVER_OFF ) {
633 HEADERS += screensaver.h
634 SOURCES += screensaver.cpp
635 }
636 RC_FILE = smplayer_os2.rc
637
638 # define the vendor part
639 DEF_FILE_VENDOR = bww bitwise works GmbH
640 DEF_FILE_VERSION = $$APPLICATION_VERSION
641 DEF_FILE_DESCRIPTION = OS/2 and OS/2-based systems port of SMPlayer
642}
643
644
645TRANSLATIONS = translations/smplayer_es.ts translations/smplayer_de.ts \
646 translations/smplayer_sk.ts translations/smplayer_it.ts \
647 translations/smplayer_fr.ts translations/smplayer_zh_CN.ts \
648 translations/smplayer_ru_RU.ts translations/smplayer_hu.ts \
649 translations/smplayer_en.ts translations/smplayer_pl.ts \
650 translations/smplayer_ja.ts translations/smplayer_nl.ts \
651 translations/smplayer_uk_UA.ts translations/smplayer_pt_BR.ts \
652 translations/smplayer_ka.ts translations/smplayer_cs.ts \
653 translations/smplayer_bg.ts translations/smplayer_tr.ts \
654 translations/smplayer_sv.ts translations/smplayer_sr.ts \
655 translations/smplayer_zh_TW.ts translations/smplayer_ro_RO.ts \
656 translations/smplayer_pt.ts translations/smplayer_el.ts \
657 translations/smplayer_fi.ts translations/smplayer_ko.ts \
658 translations/smplayer_mk.ts translations/smplayer_eu.ts \
659 translations/smplayer_ca.ts translations/smplayer_sl_SI.ts \
660 translations/smplayer_ar_SY.ts translations/smplayer_ku.ts \
661 translations/smplayer_gl.ts translations/smplayer_vi_VN.ts \
662 translations/smplayer_et.ts translations/smplayer_lt.ts \
663 translations/smplayer_da.ts translations/smplayer_hr.ts \
664 translations/smplayer_he_IL.ts translations/smplayer_th.ts \
665 translations/smplayer_ms_MY.ts translations/smplayer_uz.ts \
666 translations/smplayer_nn_NO.ts translations/smplayer_id.ts \
667 translations/smplayer_ar.ts translations/smplayer_en_GB.ts \
668 translations/smplayer_sq_AL.ts translations/smplayer_am.ts \
669 translations/smplayer_fa.ts translations/smplayer_en_US.ts
670
Note: See TracBrowser for help on using the repository browser.