source: psi/trunk/src/src.pro@ 16

Last change on this file since 16 was 16, checked in by dmik, 19 years ago

General: Added OS/2-related definitions to the build script; MAP_NDNS_TO_QDNS is used on OS/2 by default.
File size: 6.8 KB
Line 
1#
2# Psi qmake profile
3#
4
5# Configuration
6TEMPLATE = app
7CONFIG += qt thread x11
8
9#CONFIG += use_crash
10#DEFINES += GPG_DEBUG
11
12os2:DEFINES += MAP_NDNS_TO_QDNS
13
14# Executable name
15TARGET = psi
16
17os2:DESTDIR = ../psios2
18
19debug: {
20 MOC_DIR = debug/.moc
21 OBJECTS_DIR = debug/.obj
22 UI_DIR = debug/.ui
23} else {
24 MOC_DIR = .moc
25 OBJECTS_DIR = .obj
26 UI_DIR = .ui
27}
28
29# qconf
30exists(../conf.pri) {
31 include(../conf.pri)
32
33 # Shared files
34 sharedfiles.path = $$DATADIR
35 sharedfiles.files = ../README ../COPYING ../iconsets ../sound ../certs
36 INSTALLS += sharedfiles
37
38 # Widgets
39 #widgets.path = $$DATADIR/designer
40 #widgets.files = ../libpsi/psiwidgets/libpsiwidgets.so
41 #INSTALLS += widgets
42
43 # icons and desktop files
44 dt.path=$$PREFIX/share/applications/
45 dt.files = ../psi.desktop
46 icon1.path=$$PREFIX/share/icons/hicolor/16x16/apps
47 icon1.extra = cp -f ../iconsets/system/default/icon_16.png $(INSTALL_ROOT)$$icon1.path/psi.png
48 icon2.path=$$PREFIX/share/icons/hicolor/32x32/apps
49 icon2.extra = cp -f ../iconsets/system/default/icon_32.png $(INSTALL_ROOT)$$icon2.path/psi.png
50 icon3.path=$$PREFIX/share/icons/hicolor/48x48/apps
51 icon3.extra = cp -f ../iconsets/system/default/icon_48.png $(INSTALL_ROOT)$$icon3.path/psi.png
52 INSTALLS += dt icon1 icon2 icon3
53}
54
55win32: {
56 include(../conf_win32.pri)
57}
58os2: {
59 include(../conf_os2.pri)
60}
61
62# qxml
63!isEmpty(QXML_STATIC) {
64 unix: {
65 INCLUDEPATH += tools/qxml
66 HEADERS += tools/qxml/qxml.h tools/qxml/qdom.h
67 SOURCES += tools/qxml/qxml.cpp tools/qxml/qdom.cpp
68 }
69}
70
71# IPv6 ?
72#DEFINES += NO_NDNS
73
74# include some of cutestuff
75CONFIG += psics
76IRISCS_CPP = ../../cutestuff
77exists(../cutestuff) {
78 IRISCS_CPP = ../cutestuff
79}
80PSICS_CPP = tools
81include(../psics.pri)
82
83# qca
84#DEFINES += QCA_STATIC
85#QCA_PREFIX = ../qca
86#!exists(../qca) {
87# QCA_PREFIX = ../../qca/src
88#}
89#INCLUDEPATH += $$QCA_PREFIX
90#HEADERS += $$QCA_PREFIX/qca.h $$QCA_PREFIX/qcaprovider.h
91#SOURCES += $$QCA_PREFIX/qca.cpp
92
93# libxmpp
94#CONFIG += xmpp
95#XMPP_BASE = ../../xmpp
96#exists(../xmpp) {
97# XMPP_BASE = ../xmpp
98#}
99#include($$XMPP_BASE/xmpp.pri)
100
101# include Iris XMPP library
102#CONFIG += iris
103IRIS_BASE = ../../iris
104exists(../iris) {
105 IRIS_BASE = ../iris
106}
107include(../iris.pri)
108
109# include Psi library
110CONFIG += libpsi
111LIBPSI_CPP = ../../libpsi
112exists(../libpsi) {
113 LIBPSI_CPP = ../libpsi
114}
115include(../libpsi.pri)
116
117# Psi sources
118PSI_CPP = .
119
120# Header files
121HEADERS += \
122 $$PSI_CPP/varlist.h \
123 $$PSI_CPP/showtextdlg.h \
124 $$PSI_CPP/profiles.h \
125 $$PSI_CPP/profiledlg.h \
126 $$PSI_CPP/main.h \
127 $$PSI_CPP/psiaccount.h \
128 $$PSI_CPP/psicon.h \
129 $$PSI_CPP/psievent.h \
130 $$PSI_CPP/xmlconsole.h \
131 $$PSI_CPP/contactview.h \
132 $$PSI_CPP/psiiconset.h \
133 $$PSI_CPP/userlist.h \
134 $$PSI_CPP/mainwin.h \
135 $$PSI_CPP/mainwin_p.h \
136 $$PSI_CPP/rtparse.h \
137 $$PSI_CPP/common.h \
138 $$PSI_CPP/proxy.h \
139 $$PSI_CPP/accountdlg.h \
140 $$PSI_CPP/changepwdlg.h \
141 $$PSI_CPP/msgmle.h \
142 $$PSI_CPP/statusdlg.h \
143 $$PSI_CPP/eventdlg.h \
144 $$PSI_CPP/chatdlg.h \
145 $$PSI_CPP/tabdlg.h \
146 $$PSI_CPP/adduserdlg.h \
147 $$PSI_CPP/groupchatdlg.h \
148 $$PSI_CPP/infodlg.h \
149 $$PSI_CPP/eventdb.h \
150 $$PSI_CPP/historydlg.h \
151 $$PSI_CPP/servicesdlg.h \
152 $$PSI_CPP/jltest.h \
153# $$PSI_CPP/browserdlg.h \
154 $$PSI_CPP/psitoolbar.h \
155 $$PSI_CPP/passphrasedlg.h \
156 $$PSI_CPP/vcardfactory.h \
157 $$PSI_CPP/sslcertdlg.h \
158 $$PSI_CPP/qwextend.h \
159 $$PSI_CPP/tasklist.h \
160 $$PSI_CPP/discodlg.h \
161 $$PSI_CPP/alerticon.h \
162 $$PSI_CPP/psipopup.h \
163 $$PSI_CPP/psiapplication.h \
164 $$PSI_CPP/filetransdlg.h \
165 $$PSI_CPP/avatars.h \
166 $$PSI_CPP/actionlist.h \
167 $$PSI_CPP/psiactionlist.h \
168 $$PSI_CPP/xdata_widget.h \
169 $$PSI_CPP/xmpp_xdata.h
170
171# Source files
172SOURCES += \
173 $$PSI_CPP/varlist.cpp \
174 $$PSI_CPP/showtextdlg.cpp \
175 $$PSI_CPP/psi_profiles.cpp \
176 $$PSI_CPP/profiledlg.cpp \
177 $$PSI_CPP/main.cpp \
178 $$PSI_CPP/psiaccount.cpp \
179 $$PSI_CPP/psicon.cpp \
180 $$PSI_CPP/psievent.cpp \
181 $$PSI_CPP/xmlconsole.cpp \
182 $$PSI_CPP/contactview.cpp \
183 $$PSI_CPP/psiiconset.cpp \
184 $$PSI_CPP/userlist.cpp \
185 $$PSI_CPP/mainwin.cpp \
186 $$PSI_CPP/mainwin_p.cpp \
187 $$PSI_CPP/rtparse.cpp \
188 $$PSI_CPP/common.cpp \
189 $$PSI_CPP/proxy.cpp \
190 $$PSI_CPP/accountdlg.cpp \
191 $$PSI_CPP/changepwdlg.cpp \
192 $$PSI_CPP/msgmle.cpp \
193 $$PSI_CPP/statusdlg.cpp \
194 $$PSI_CPP/eventdlg.cpp \
195 $$PSI_CPP/chatdlg.cpp \
196 $$PSI_CPP/tabdlg.cpp \
197 $$PSI_CPP/adduserdlg.cpp \
198 $$PSI_CPP/groupchatdlg.cpp \
199 $$PSI_CPP/infodlg.cpp \
200 $$PSI_CPP/eventdb.cpp \
201 $$PSI_CPP/historydlg.cpp \
202 $$PSI_CPP/servicesdlg.cpp \
203 $$PSI_CPP/jltest.cpp \
204# $$PSI_CPP/browserdlg.cpp \
205 $$PSI_CPP/psitoolbar.cpp \
206 $$PSI_CPP/passphrasedlg.cpp \
207 $$PSI_CPP/vcardfactory.cpp \
208 $$PSI_CPP/sslcertdlg.cpp \
209 $$PSI_CPP/qwextend.cpp \
210 $$PSI_CPP/discodlg.cpp \
211 $$PSI_CPP/alerticon.cpp \
212 $$PSI_CPP/psipopup.cpp \
213 $$PSI_CPP/psiapplication.cpp \
214 $$PSI_CPP/filetransdlg.cpp \
215 $$PSI_CPP/avatars.cpp \
216 $$PSI_CPP/actionlist.cpp \
217 $$PSI_CPP/psiactionlist.cpp \
218 $$PSI_CPP/xdata_widget.cpp \
219 $$PSI_CPP/xmpp_xdata.cpp
220mac {
221 contains( DEFINES, HAVE_GROWL ) {
222 HEADERS += $$PSI_CPP/psigrowlnotifier.h
223 SOURCES += $$PSI_CPP/psigrowlnotifier.cpp
224 }
225}
226
227# Qt Designer interfaces
228INTERFACES = \
229 $$PSI_CPP/ui_profileopen.ui \
230 $$PSI_CPP/ui_profilemanage.ui \
231 $$PSI_CPP/ui_profilenew.ui \
232 $$PSI_CPP/ui_proxy.ui \
233 $$PSI_CPP/ui_pgpkey.ui \
234 $$PSI_CPP/ui_accountmanage.ui \
235 $$PSI_CPP/ui_accountadd.ui \
236 $$PSI_CPP/ui_accountreg.ui \
237 $$PSI_CPP/ui_accountremove.ui \
238 $$PSI_CPP/ui_accountmodify.ui \
239 $$PSI_CPP/ui_changepw.ui \
240 $$PSI_CPP/ui_addurl.ui \
241 $$PSI_CPP/ui_adduser.ui \
242 $$PSI_CPP/ui_gcjoin.ui \
243 $$PSI_CPP/ui_info.ui \
244 $$PSI_CPP/ui_search.ui \
245 $$PSI_CPP/ui_about.ui \
246# $$PSI_CPP/ui_browser.ui \
247 $$PSI_CPP/ui_passphrase.ui \
248 $$PSI_CPP/ui_sslcert.ui \
249 $$PSI_CPP/ui_disco.ui \
250 $$PSI_CPP/ui_tip.ui \
251 $$PSI_CPP/ui_filetrans.ui
252
253# options dialog
254include(options/options.pri)
255
256LANG_PATH = ../lang
257
258# Translations
259TRANSLATIONS = \
260 $$LANG_PATH/psi_ar.ts \
261 $$LANG_PATH/psi_ca.ts \
262 $$LANG_PATH/psi_cs.ts \
263 $$LANG_PATH/psi_da.ts \
264 $$LANG_PATH/psi_de.ts \
265 $$LANG_PATH/psi_el.ts \
266 $$LANG_PATH/psi_eo.ts \
267 $$LANG_PATH/psi_es.ts \
268 $$LANG_PATH/psi_fi.ts \
269 $$LANG_PATH/psi_fr.ts \
270 $$LANG_PATH/psi_it.ts \
271 $$LANG_PATH/psi_jp.ts \
272 $$LANG_PATH/psi_mk.ts \
273 $$LANG_PATH/psi_nl.ts \
274 $$LANG_PATH/psi_pl.ts \
275 $$LANG_PATH/psi_pt.ts \
276 $$LANG_PATH/psi_ptbr.ts \
277 $$LANG_PATH/psi_ru.ts \
278 $$LANG_PATH/psi_se.ts \
279 $$LANG_PATH/psi_sk.ts \
280 $$LANG_PATH/psi_sr.ts \
281 $$LANG_PATH/psi_zh.ts
282
283# Platform specifics
284unix:!mac {
285 QMAKE_POST_LINK = rm -f ../psi ; ln -s src/psi ../psi
286}
287win32: {
288 RC_FILE = ../win32/psi_win32.rc
289
290 # buggy MSVC workaround
291 contains(MAKEFILE_GENERATOR, MSVC): QMAKE_LFLAGS += /FORCE:MULTIPLE
292 contains(MAKEFILE_GENERATOR, MSVC.NET): QMAKE_LFLAGS += /FORCE:MULTIPLE
293}
294os2: {
295 RC_FILE = ../os2/psi_os2.rc
296}
297mac: {
298 QMAKE_LFLAGS += -framework Carbon -framework IOKit
299 QMAKE_INFO_PLIST = ../mac/Info.plist
300 RC_FILE = ../mac/application.icns
301 QMAKE_POST_LINK = cp -R ../COPYING ../README ../certs ../iconsets ../sound $(DESTDIR)../Resources ; echo "APPLpsi " > $(DESTDIR)../PkgInfo
302}
Note: See TracBrowser for help on using the repository browser.