| 1 | TEMPLATE=lib
|
|---|
| 2 | TARGET=QtDesigner
|
|---|
| 3 | os2:TARGET_SHORT=QtDsgn
|
|---|
| 4 | QT += xml
|
|---|
| 5 | contains(QT_CONFIG, reduce_exports):CONFIG += hide_symbols
|
|---|
| 6 | CONFIG += qt
|
|---|
| 7 | win32|mac: CONFIG += debug_and_release
|
|---|
| 8 | DESTDIR = ../../../../lib
|
|---|
| 9 | !wince*:DLLDESTDIR = ../../../../bin
|
|---|
| 10 |
|
|---|
| 11 | unix:QMAKE_PKGCONFIG_REQUIRES += QtXml
|
|---|
| 12 |
|
|---|
| 13 | include(../../../../src/qt_version.pri)
|
|---|
| 14 | include(../../../../src/qt_targets.pri)
|
|---|
| 15 | QMAKE_TARGET_PRODUCT = Designer
|
|---|
| 16 | QMAKE_TARGET_DESCRIPTION = Graphical user interface designer.
|
|---|
| 17 |
|
|---|
| 18 | !contains(CONFIG, static) {
|
|---|
| 19 | CONFIG += dll
|
|---|
| 20 |
|
|---|
| 21 | DEFINES += \
|
|---|
| 22 | QDESIGNER_SDK_LIBRARY \
|
|---|
| 23 | QDESIGNER_EXTENSION_LIBRARY \
|
|---|
| 24 | QDESIGNER_UILIB_LIBRARY \
|
|---|
| 25 | QDESIGNER_SHARED_LIBRARY
|
|---|
| 26 | } else {
|
|---|
| 27 | DEFINES += QT_DESIGNER_STATIC
|
|---|
| 28 | }
|
|---|
| 29 |
|
|---|
| 30 | #load up the headers info
|
|---|
| 31 | CONFIG += qt_install_headers
|
|---|
| 32 | HEADERS_PRI = $$QT_BUILD_TREE/include/QtDesigner/headers.pri
|
|---|
| 33 | include($$HEADERS_PRI, "", true)|clear(HEADERS_PRI)
|
|---|
| 34 |
|
|---|
| 35 | #mac frameworks
|
|---|
| 36 | mac:CONFIG += explicitlib
|
|---|
| 37 | mac:!static:contains(QT_CONFIG, qt_framework) {
|
|---|
| 38 | QMAKE_FRAMEWORK_BUNDLE_NAME = $$TARGET
|
|---|
| 39 | CONFIG += lib_bundle qt_no_framework_direct_includes qt_framework
|
|---|
| 40 | CONFIG(debug, debug|release) {
|
|---|
| 41 | !build_pass:CONFIG += build_all
|
|---|
| 42 | } else { #release
|
|---|
| 43 | !debug_and_release|build_pass {
|
|---|
| 44 | CONFIG -= qt_install_headers #no need to install these as well
|
|---|
| 45 | FRAMEWORK_HEADERS.version = Versions
|
|---|
| 46 | FRAMEWORK_HEADERS.files = $$SYNCQT.HEADER_FILES $$SYNCQT.HEADER_CLASSES
|
|---|
| 47 | FRAMEWORK_HEADERS.path = Headers
|
|---|
| 48 | }
|
|---|
| 49 | QMAKE_BUNDLE_DATA += FRAMEWORK_HEADERS
|
|---|
| 50 | }
|
|---|
| 51 | }
|
|---|
| 52 |
|
|---|
| 53 | include(extension/extension.pri)
|
|---|
| 54 | include(sdk/sdk.pri)
|
|---|
| 55 | include(uilib/uilib.pri)
|
|---|
| 56 | include(shared/shared.pri)
|
|---|
| 57 | PRECOMPILED_HEADER=lib_pch.h
|
|---|
| 58 |
|
|---|
| 59 | include(../sharedcomponents.pri)
|
|---|
| 60 | include(../components/component.pri)
|
|---|
| 61 |
|
|---|
| 62 | target.path=$$[QT_INSTALL_LIBS]
|
|---|
| 63 | INSTALLS += target
|
|---|
| 64 | win32|os2 {
|
|---|
| 65 | dlltarget.path=$$[QT_INSTALL_BINS]
|
|---|
| 66 | INSTALLS += dlltarget
|
|---|
| 67 | }
|
|---|
| 68 |
|
|---|
| 69 |
|
|---|
| 70 | qt_install_headers {
|
|---|
| 71 | designer_headers.files = $$SYNCQT.HEADER_FILES $$SYNCQT.HEADER_CLASSES
|
|---|
| 72 | designer_headers.path = $$[QT_INSTALL_HEADERS]/QtDesigner
|
|---|
| 73 | INSTALLS += designer_headers
|
|---|
| 74 | }
|
|---|
