source: trunk/tools/assistant/compat/lib/lib.pro@ 369

Last change on this file since 369 was 369, checked in by Dmitry A. Kuminov, 15 years ago

Make sure components in tools/ obey TARGET_SHORT if it's defined.

File size: 2.3 KB
Line 
1TEMPLATE = lib
2QT += network
3TARGET = QtAssistantClient
4isEmpty(QT_MAJOR_VERSION) {
5 VERSION=4.3.0
6} else {
7 VERSION=$${QT_MAJOR_VERSION}.$${QT_MINOR_VERSION}.$${QT_PATCH_VERSION}
8}
9
10CONFIG += qt warn_on
11mac|win32:CONFIG += debug_and_release
12mac:unix:CONFIG += explicitlib
13CONFIG -= dll
14
15HEADERS = qassistantclient.h \
16 qassistantclient_global.h
17SOURCES = qassistantclient.cpp
18
19DESTDIR = ../../../../lib
20DLLDESTDIR = ../../../../bin
21
22unix {
23 QMAKE_CFLAGS += $$QMAKE_CFLAGS_SHLIB
24 QMAKE_CXXFLAGS += $$QMAKE_CXXFLAGS_SHLIB
25}
26
27DEFINES += QT_ASSISTANT_CLIENT_LIBRARY
28contains(CONFIG, static) {
29 DEFINES += QT_ASSISTANT_CLIENT_STATIC
30}
31
32#load up the headers info
33CONFIG += qt_install_headers
34HEADERS_PRI = $$QT_BUILD_TREE/include/QtAssistant/headers.pri
35include($$HEADERS_PRI)|clear(HEADERS_PRI)
36
37#mac frameworks
38mac:!static:contains(QT_CONFIG, qt_framework) {
39 TARGET = QtAssistant # Change the name to match the headers
40 QMAKE_FRAMEWORK_BUNDLE_NAME = $$TARGET
41 CONFIG += lib_bundle qt_no_framework_direct_includes qt_framework
42 CONFIG(debug, debug|release) {
43 !build_pass:CONFIG += build_all
44 } else { #release
45 !debug_and_release|build_pass {
46 CONFIG -= qt_install_headers #no need to install these as well
47 FRAMEWORK_HEADERS.version = Versions
48 FRAMEWORK_HEADERS.files = $$SYNCQT.HEADER_FILES $$SYNCQT.HEADER_CLASSES
49 FRAMEWORK_HEADERS.path = Headers
50 }
51 QMAKE_BUNDLE_DATA += FRAMEWORK_HEADERS
52 }
53}
54
55TARGET = $$qtLibraryTarget($$TARGET$$QT_LIBINFIX) #done towards the end
56!isEmpty(TARGET_SHORT):TARGET_SHORT = $$qtLibraryTarget($$TARGET_SHORT$$QT_LIBINFIX) #do this towards the end
57
58target.path=$$[QT_INSTALL_LIBS]
59INSTALLS += target
60win32 {
61 dlltarget.path=$$[QT_INSTALL_BINS]
62 INSTALLS += dlltarget
63}
64
65qt_install_headers {
66 assistant_headers.files = $$SYNCQT.HEADER_FILES $$SYNCQT.HEADER_CLASSES
67 assistant_headers.path = $$[QT_INSTALL_HEADERS]/QtAssistant
68 INSTALLS += assistant_headers
69}
70
71unix {
72 CONFIG += create_pc
73 QMAKE_PKGCONFIG_LIBDIR = $$[QT_INSTALL_LIBS]
74 QMAKE_PKGCONFIG_INCDIR = $$[QT_INSTALL_HEADERS]/QtAssistant
75 QMAKE_PKGCONFIG_CFLAGS = -I$$[QT_INSTALL_HEADERS]
76 QMAKE_PKGCONFIG_DESTDIR = pkgconfig
77 QMAKE_PKGCONFIG_REQUIRES += QtNetwork
78}
79
Note: See TracBrowser for help on using the repository browser.