source: trunk/src/src.pro@ 64

Last change on this file since 64 was 60, checked in by Dmitry A. Kuminov, 16 years ago

corelib: Alter .pro files to take OS/2 into account (many modules are disabled yet).
File size: 7.3 KB
Line 
1TEMPLATE = subdirs
2
3# this order is important
4unset(SRC_SUBDIRS)
5win32:SRC_SUBDIRS += src_winmain
6wince*:{
7 SRC_SUBDIRS += src_corelib src_xml src_gui src_sql src_network src_script src_testlib
8} else {
9 SRC_SUBDIRS += src_tools_bootstrap src_tools_moc src_tools_rcc src_tools_uic src_corelib src_xml src_network src_gui src_sql src_script src_testlib
10 contains(QT_CONFIG, qt3support): SRC_SUBDIRS += src_qt3support
11 contains(QT_CONFIG, dbus):SRC_SUBDIRS += src_dbus
12 !cross_compile {
13 contains(QT_CONFIG, qt3support): SRC_SUBDIRS += src_tools_uic3
14 }
15}
16win32:!contains(QT_EDITION, OpenSource|Console): {
17 SRC_SUBDIRS += src_activeqt
18 !wince*: SRC_SUBDIRS += src_tools_idc
19}
20
21contains(QT_CONFIG, opengl)|contains(QT_CONFIG, opengles1)|contains(QT_CONFIG, opengles2): SRC_SUBDIRS += src_opengl
22contains(QT_CONFIG, xmlpatterns): SRC_SUBDIRS += src_xmlpatterns
23contains(QT_CONFIG, phonon): SRC_SUBDIRS += src_phonon
24contains(QT_CONFIG, svg): SRC_SUBDIRS += src_svg
25contains(QT_CONFIG, webkit) {
26 #exists($$QT_SOURCE_TREE/src/3rdparty/webkit/JavaScriptCore/JavaScriptCore.pro): SRC_SUBDIRS += src_javascriptcore
27 SRC_SUBDIRS += src_webkit
28}
29contains(QT_CONFIG, scripttools): SRC_SUBDIRS += src_scripttools
30SRC_SUBDIRS += src_plugins
31
32# @todo on OS/2, forcefully remove modules that are not yet ready
33os2 {
34 SRC_SUBDIRS -= src_tools_uic src_network src_gui src_sql src_qt3support src_tools_uic3 src_svg
35}
36
37src_winmain.subdir = $$QT_SOURCE_TREE/src/winmain
38src_winmain.target = sub-winmain
39src_tools_bootstrap.subdir = $$QT_SOURCE_TREE/src/tools/bootstrap
40src_tools_bootstrap.target = sub-tools-bootstrap
41src_tools_moc.subdir = $$QT_SOURCE_TREE/src/tools/moc
42src_tools_moc.target = sub-moc
43src_tools_rcc.subdir = $$QT_SOURCE_TREE/src/tools/rcc
44src_tools_rcc.target = sub-rcc
45src_tools_uic.subdir = $$QT_SOURCE_TREE/src/tools/uic
46src_tools_uic.target = sub-uic
47src_corelib.subdir = $$QT_SOURCE_TREE/src/corelib
48src_corelib.target = sub-corelib
49src_xml.subdir = $$QT_SOURCE_TREE/src/xml
50src_xml.target = sub-xml
51src_xmlpatterns.subdir = $$QT_SOURCE_TREE/src/xmlpatterns
52src_xmlpatterns.target = sub-xmlpatterns
53src_dbus.subdir = $$QT_SOURCE_TREE/src/dbus
54src_dbus.target = sub-dbus
55src_gui.subdir = $$QT_SOURCE_TREE/src/gui
56src_gui.target = sub-gui
57src_sql.subdir = $$QT_SOURCE_TREE/src/sql
58src_sql.target = sub-sql
59src_network.subdir = $$QT_SOURCE_TREE/src/network
60src_network.target = sub-network
61src_svg.subdir = $$QT_SOURCE_TREE/src/svg
62src_svg.target = sub-svg
63src_script.subdir = $$QT_SOURCE_TREE/src/script
64src_script.target = sub-script
65src_scripttools.subdir = $$QT_SOURCE_TREE/src/scripttools
66src_scripttools.target = sub-scripttools
67src_opengl.subdir = $$QT_SOURCE_TREE/src/opengl
68src_opengl.target = sub-opengl
69src_qt3support.subdir = $$QT_SOURCE_TREE/src/qt3support
70src_qt3support.target = sub-qt3support
71src_phonon.subdir = $$QT_SOURCE_TREE/src/phonon
72src_phonon.target = sub-phonon
73src_tools_uic3.subdir = $$QT_SOURCE_TREE/src/tools/uic3
74src_tools_uic3.target = sub-uic3
75src_activeqt.subdir = $$QT_SOURCE_TREE/src/activeqt
76src_activeqt.target = sub-activeqt
77src_tools_idc.subdir = $$QT_SOURCE_TREE/src/tools/idc
78src_tools_idc.target = sub-idc
79src_plugins.subdir = $$QT_SOURCE_TREE/src/plugins
80src_plugins.target = sub-plugins
81src_testlib.subdir = $$QT_SOURCE_TREE/src/testlib
82src_testlib.target = sub-testlib
83src_javascriptcore.subdir = $$QT_SOURCE_TREE/src/3rdparty/webkit/JavaScriptCore
84src_javascriptcore.target = sub-javascriptcore
85src_webkit.subdir = $$QT_SOURCE_TREE/src/3rdparty/webkit/WebCore
86src_webkit.target = sub-webkit
87
88#CONFIG += ordered
89!wince*:!ordered {
90 src_tools_moc.depends = src_tools_bootstrap
91 src_tools_rcc.depends = src_tools_bootstrap
92 src_tools_uic.depends = src_tools_bootstrap
93 src_corelib.depends = src_tools_moc src_tools_rcc
94 src_gui.depends = src_corelib src_tools_uic
95 embedded: src_gui.depends += src_network
96 src_xml.depends = src_corelib
97 src_xmlpatterns.depends = src_corelib src_network
98 src_dbus.depends = src_corelib src_xml
99 src_svg.depends = src_xml src_gui
100 src_script.depends = src_corelib
101 src_scripttools.depends = src_script src_gui src_network
102 src_network.depends = src_corelib
103 src_opengl.depends = src_gui
104 src_sql.depends = src_corelib
105 src_testlib.depends = src_corelib
106 src_qt3support.depends = src_gui src_xml src_network src_sql
107 src_phonon.depends = src_gui
108 src_tools_uic3.depends = src_qt3support src_xml
109 src_tools_idc.depends = src_corelib
110 src_tools_activeqt.depends = src_tools_idc src_gui
111 src_plugins.depends = src_gui src_sql src_svg
112 contains(QT_CONFIG, webkit) {
113 src_webkit.depends = src_gui src_sql src_network src_xml
114 #exists($$QT_SOURCE_TREE/src/3rdparty/webkit/JavaScriptCore/JavaScriptCore.pro): src_webkit.depends += src_javascriptcore
115 }
116 contains(QT_CONFIG, qt3support): src_plugins.depends += src_qt3support
117 contains(QT_CONFIG, dbus):{
118 src_plugins.depends += src_dbus
119 src_phonon.depends += src_dbus
120 }
121}
122
123# This creates a sub-src rule
124sub_src_target.CONFIG = recursive
125sub_src_target.recurse = $$SRC_SUBDIRS
126sub_src_target.target = sub-src
127sub_src_target.recurse_target =
128QMAKE_EXTRA_TARGETS += sub_src_target
129
130# This gives us a top level debug/release
131EXTRA_DEBUG_TARGETS =
132EXTRA_RELEASE_TARGETS =
133for(subname, SRC_SUBDIRS) {
134 subdir = $$subname
135 !isEmpty($${subname}.subdir):subdir = $$eval($${subname}.subdir)
136 subpro = $$subdir/$${basename(subdir)}.pro
137 !exists($$subpro):next()
138 subtarget = $$replace(subdir, [^A-Za-z0-9], _)
139 reg_src = $$replace(QT_SOURCE_TREE, \\\\, \\\\)
140 subdir = $$replace(subdir, $$reg_src, $$QT_BUILD_TREE)
141 subdir = $$replace(subdir, /, $$QMAKE_DIR_SEP)
142 subdir = $$replace(subdir, \\\\, $$QMAKE_DIR_SEP)
143 SUB_TEMPLATE = $$list($$fromfile($$subpro, TEMPLATE))
144 !isEqual(subname, src_tools_bootstrap):if(isEqual($$SUB_TEMPLATE, lib) | isEqual($$SUB_TEMPLATE, subdirs) | isEqual(subname, src_tools_idc) | isEqual(subname, src_tools_uic3)):!separate_debug_info {
145 #debug
146 eval(debug-$${subtarget}.depends = $${subdir}\$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_DEBUG_TARGETS)
147 eval(debug-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) debug))
148 EXTRA_DEBUG_TARGETS += debug-$${subtarget}
149 QMAKE_EXTRA_TARGETS += debug-$${subtarget}
150 #release
151 eval(release-$${subtarget}.depends = $${subdir}\$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_RELEASE_TARGETS)
152 eval(release-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) release))
153 EXTRA_RELEASE_TARGETS += release-$${subtarget}
154 QMAKE_EXTRA_TARGETS += release-$${subtarget}
155 } else { #do not have a real debug target/release
156 #debug
157 eval(debug-$${subtarget}.depends = $${subdir}\$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_DEBUG_TARGETS)
158 eval(debug-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) first))
159 EXTRA_DEBUG_TARGETS += debug-$${subtarget}
160 QMAKE_EXTRA_TARGETS += debug-$${subtarget}
161 #release
162 eval(release-$${subtarget}.depends = $${subdir}\$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_RELEASE_TARGETS)
163 eval(release-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) first))
164 EXTRA_RELEASE_TARGETS += release-$${subtarget}
165 QMAKE_EXTRA_TARGETS += release-$${subtarget}
166 }
167}
168debug.depends = $$EXTRA_DEBUG_TARGETS
169release.depends = $$EXTRA_RELEASE_TARGETS
170QMAKE_EXTRA_TARGETS += debug release
171
172SUBDIRS += $$SRC_SUBDIRS
173
Note: See TracBrowser for help on using the repository browser.