source: trunk/src/src.pro@ 252

Last change on this file since 252 was 252, checked in by Dmitry A. Kuminov, 16 years ago

3rdparty: Added sketch of the Extended system tray XCenter plug-in.
File size: 7.3 KB
Line 
1TEMPLATE = subdirs
2
3# this order is important
4unset(SRC_SUBDIRS)
5win32:SRC_SUBDIRS += src_winmain
6wince*:{
7 SRC_SUBDIRS += src_corelib src_xml src_gui src_sql src_network src_script src_testlib
8} else {
9 SRC_SUBDIRS += src_tools_bootstrap src_tools_moc src_tools_rcc src_tools_uic src_corelib src_xml src_network src_gui src_sql src_script src_testlib
10 contains(QT_CONFIG, qt3support): SRC_SUBDIRS += src_qt3support
11 contains(QT_CONFIG, dbus):SRC_SUBDIRS += src_dbus
12 !cross_compile {
13 contains(QT_CONFIG, qt3support): SRC_SUBDIRS += src_tools_uic3
14 }
15}
16win32:!contains(QT_EDITION, OpenSource|Console): {
17 SRC_SUBDIRS += src_activeqt
18 !wince*: SRC_SUBDIRS += src_tools_idc
19}
20
21contains(QT_CONFIG, opengl)|contains(QT_CONFIG, opengles1)|contains(QT_CONFIG, opengles2): SRC_SUBDIRS += src_opengl
22contains(QT_CONFIG, xmlpatterns): SRC_SUBDIRS += src_xmlpatterns
23contains(QT_CONFIG, phonon): SRC_SUBDIRS += src_phonon
24contains(QT_CONFIG, svg): SRC_SUBDIRS += src_svg
25contains(QT_CONFIG, webkit) {
26 #exists($$QT_SOURCE_TREE/src/3rdparty/webkit/JavaScriptCore/JavaScriptCore.pro): SRC_SUBDIRS += src_javascriptcore
27 SRC_SUBDIRS += src_webkit
28}
29contains(QT_CONFIG, scripttools): SRC_SUBDIRS += src_scripttools
30SRC_SUBDIRS += src_plugins
31
32os2:SRC_SUBDIRS += src_xsystray
33
34src_winmain.subdir = $$QT_SOURCE_TREE/src/winmain
35src_winmain.target = sub-winmain
36src_tools_bootstrap.subdir = $$QT_SOURCE_TREE/src/tools/bootstrap
37src_tools_bootstrap.target = sub-tools-bootstrap
38src_tools_moc.subdir = $$QT_SOURCE_TREE/src/tools/moc
39src_tools_moc.target = sub-moc
40src_tools_rcc.subdir = $$QT_SOURCE_TREE/src/tools/rcc
41src_tools_rcc.target = sub-rcc
42src_tools_uic.subdir = $$QT_SOURCE_TREE/src/tools/uic
43src_tools_uic.target = sub-uic
44src_corelib.subdir = $$QT_SOURCE_TREE/src/corelib
45src_corelib.target = sub-corelib
46src_xml.subdir = $$QT_SOURCE_TREE/src/xml
47src_xml.target = sub-xml
48src_xmlpatterns.subdir = $$QT_SOURCE_TREE/src/xmlpatterns
49src_xmlpatterns.target = sub-xmlpatterns
50src_dbus.subdir = $$QT_SOURCE_TREE/src/dbus
51src_dbus.target = sub-dbus
52src_gui.subdir = $$QT_SOURCE_TREE/src/gui
53src_gui.target = sub-gui
54src_sql.subdir = $$QT_SOURCE_TREE/src/sql
55src_sql.target = sub-sql
56src_network.subdir = $$QT_SOURCE_TREE/src/network
57src_network.target = sub-network
58src_svg.subdir = $$QT_SOURCE_TREE/src/svg
59src_svg.target = sub-svg
60src_script.subdir = $$QT_SOURCE_TREE/src/script
61src_script.target = sub-script
62src_scripttools.subdir = $$QT_SOURCE_TREE/src/scripttools
63src_scripttools.target = sub-scripttools
64src_opengl.subdir = $$QT_SOURCE_TREE/src/opengl
65src_opengl.target = sub-opengl
66src_qt3support.subdir = $$QT_SOURCE_TREE/src/qt3support
67src_qt3support.target = sub-qt3support
68src_phonon.subdir = $$QT_SOURCE_TREE/src/phonon
69src_phonon.target = sub-phonon
70src_tools_uic3.subdir = $$QT_SOURCE_TREE/src/tools/uic3
71src_tools_uic3.target = sub-uic3
72src_activeqt.subdir = $$QT_SOURCE_TREE/src/activeqt
73src_activeqt.target = sub-activeqt
74src_tools_idc.subdir = $$QT_SOURCE_TREE/src/tools/idc
75src_tools_idc.target = sub-idc
76src_plugins.subdir = $$QT_SOURCE_TREE/src/plugins
77src_plugins.target = sub-plugins
78src_testlib.subdir = $$QT_SOURCE_TREE/src/testlib
79src_testlib.target = sub-testlib
80src_javascriptcore.subdir = $$QT_SOURCE_TREE/src/3rdparty/webkit/JavaScriptCore
81src_javascriptcore.target = sub-javascriptcore
82src_webkit.subdir = $$QT_SOURCE_TREE/src/3rdparty/webkit/WebCore
83src_webkit.target = sub-webkit
84src_xsystray.subdir = $$QT_SOURCE_TREE/src/3rdparty/os2/xsystray
85src_xsystray.target = sub-xsystray
86
87#CONFIG += ordered
88!wince*:!ordered {
89 src_tools_moc.depends = src_tools_bootstrap
90 src_tools_rcc.depends = src_tools_bootstrap
91 src_tools_uic.depends = src_tools_bootstrap
92 src_corelib.depends = src_tools_moc src_tools_rcc
93 src_gui.depends = src_corelib src_tools_uic
94 embedded: src_gui.depends += src_network
95 src_xml.depends = src_corelib
96 src_xmlpatterns.depends = src_corelib src_network
97 src_dbus.depends = src_corelib src_xml
98 src_svg.depends = src_xml src_gui
99 src_script.depends = src_corelib
100 src_scripttools.depends = src_script src_gui src_network
101 src_network.depends = src_corelib
102 src_opengl.depends = src_gui
103 src_sql.depends = src_corelib
104 src_testlib.depends = src_corelib
105 src_qt3support.depends = src_gui src_xml src_network src_sql
106 src_phonon.depends = src_gui
107 src_tools_uic3.depends = src_qt3support src_xml
108 src_tools_idc.depends = src_corelib
109 src_tools_activeqt.depends = src_tools_idc src_gui
110 src_plugins.depends = src_gui src_sql src_svg
111 contains(QT_CONFIG, webkit) {
112 src_webkit.depends = src_gui src_sql src_network src_xml
113 #exists($$QT_SOURCE_TREE/src/3rdparty/webkit/JavaScriptCore/JavaScriptCore.pro): src_webkit.depends += src_javascriptcore
114 }
115 contains(QT_CONFIG, qt3support): src_plugins.depends += src_qt3support
116 contains(QT_CONFIG, dbus):{
117 src_plugins.depends += src_dbus
118 src_phonon.depends += src_dbus
119 }
120}
121
122# This creates a sub-src rule
123sub_src_target.CONFIG = recursive
124sub_src_target.recurse = $$SRC_SUBDIRS
125sub_src_target.target = sub-src
126sub_src_target.recurse_target =
127QMAKE_EXTRA_TARGETS += sub_src_target
128
129# This gives us a top level debug/release
130EXTRA_DEBUG_TARGETS =
131EXTRA_RELEASE_TARGETS =
132for(subname, SRC_SUBDIRS) {
133 subdir = $$subname
134 !isEmpty($${subname}.subdir):subdir = $$eval($${subname}.subdir)
135 subpro = $$subdir/$${basename(subdir)}.pro
136 !exists($$subpro):next()
137 subtarget = $$replace(subdir, [^A-Za-z0-9], _)
138 reg_src = $$replace(QT_SOURCE_TREE, \\\\, \\\\)
139 subdir = $$replace(subdir, $$reg_src, $$QT_BUILD_TREE)
140 subdir = $$replace(subdir, /, $$QMAKE_DIR_SEP)
141 subdir = $$replace(subdir, \\\\, $$QMAKE_DIR_SEP)
142 SUB_TEMPLATE = $$list($$fromfile($$subpro, TEMPLATE))
143 !isEqual(subname, src_tools_bootstrap):if(isEqual($$SUB_TEMPLATE, lib) | isEqual($$SUB_TEMPLATE, subdirs) | isEqual(subname, src_tools_idc) | isEqual(subname, src_tools_uic3)):!separate_debug_info {
144 #debug
145 eval(debug-$${subtarget}.depends = $${subdir}\$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_DEBUG_TARGETS)
146 eval(debug-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) debug))
147 EXTRA_DEBUG_TARGETS += debug-$${subtarget}
148 QMAKE_EXTRA_TARGETS += debug-$${subtarget}
149 #release
150 eval(release-$${subtarget}.depends = $${subdir}\$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_RELEASE_TARGETS)
151 eval(release-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) release))
152 EXTRA_RELEASE_TARGETS += release-$${subtarget}
153 QMAKE_EXTRA_TARGETS += release-$${subtarget}
154 } else { #do not have a real debug target/release
155 #debug
156 eval(debug-$${subtarget}.depends = $${subdir}\$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_DEBUG_TARGETS)
157 eval(debug-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) first))
158 EXTRA_DEBUG_TARGETS += debug-$${subtarget}
159 QMAKE_EXTRA_TARGETS += debug-$${subtarget}
160 #release
161 eval(release-$${subtarget}.depends = $${subdir}\$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_RELEASE_TARGETS)
162 eval(release-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) first))
163 EXTRA_RELEASE_TARGETS += release-$${subtarget}
164 QMAKE_EXTRA_TARGETS += release-$${subtarget}
165 }
166}
167debug.depends = $$EXTRA_DEBUG_TARGETS
168release.depends = $$EXTRA_RELEASE_TARGETS
169QMAKE_EXTRA_TARGETS += debug release
170
171SUBDIRS += $$SRC_SUBDIRS
172
Note: See TracBrowser for help on using the repository browser.