| 1 | TARGET = QtScript
|
|---|
| 2 | os2:TARGET_SHORT = QtScri
|
|---|
| 3 | QPRO_PWD = $$PWD
|
|---|
| 4 | QT = core
|
|---|
| 5 | DEFINES += JSC=QTJSC jscyyparse=qtjscyyparse jscyylex=qtjscyylex jscyyerror=qtjscyyerror WTF=QTWTF
|
|---|
| 6 | DEFINES += QT_BUILD_SCRIPT_LIB
|
|---|
| 7 | DEFINES += QT_NO_USING_NAMESPACE
|
|---|
| 8 | DEFINES += QLALR_NO_QSCRIPTGRAMMAR_DEBUG_INFO
|
|---|
| 9 | #win32-msvc*|win32-icc:QMAKE_LFLAGS += /BASE:0x66000000 ### FIXME
|
|---|
| 10 |
|
|---|
| 11 | unix:QMAKE_PKGCONFIG_REQUIRES = QtCore
|
|---|
| 12 |
|
|---|
| 13 | include(../qbase.pri)
|
|---|
| 14 |
|
|---|
| 15 | CONFIG += building-libs
|
|---|
| 16 |
|
|---|
| 17 | # FIXME: shared the statically built JavaScriptCore
|
|---|
| 18 |
|
|---|
| 19 | # Fetch the base WebKit directory from the WEBKITDIR environment variable;
|
|---|
| 20 | # fall back to src/3rdparty otherwise
|
|---|
| 21 | WEBKITDIR = $$(WEBKITDIR)
|
|---|
| 22 | isEmpty(WEBKITDIR) {
|
|---|
| 23 | WEBKITDIR = $$PWD/../3rdparty/javascriptcore
|
|---|
| 24 | GENERATED_SOURCES_DIR = generated
|
|---|
| 25 | } else {
|
|---|
| 26 | message(using external WebKit from $$WEBKITDIR)
|
|---|
| 27 | CONFIG -= QTDIR_build
|
|---|
| 28 | }
|
|---|
| 29 | include($$WEBKITDIR/WebKit.pri)
|
|---|
| 30 |
|
|---|
| 31 | # Disable a few warnings on Windows.
|
|---|
| 32 | # These are in addition to the ones disabled in WebKit.pri
|
|---|
| 33 | win32-msvc*: QMAKE_CXXFLAGS += -wd4396 -wd4099
|
|---|
| 34 |
|
|---|
| 35 | # Windows CE-specific stuff copied from WebCore.pro
|
|---|
| 36 | # ### Should rather be in JavaScriptCore.pri?
|
|---|
| 37 | wince* {
|
|---|
| 38 | INCLUDEPATH += $$WEBKITDIR/JavaScriptCore/os-wince
|
|---|
| 39 | INCLUDEPATH += $$WEBKITDIR/JavaScriptCore/os-win32
|
|---|
| 40 | LIBS += -lmmtimer
|
|---|
| 41 | }
|
|---|
| 42 |
|
|---|
| 43 | mac {
|
|---|
| 44 | DEFINES += ENABLE_JSC_MULTIPLE_THREADS=0
|
|---|
| 45 | LIBS_PRIVATE += -framework AppKit
|
|---|
| 46 | }
|
|---|
| 47 |
|
|---|
| 48 | include($$WEBKITDIR/JavaScriptCore/JavaScriptCore.pri)
|
|---|
| 49 |
|
|---|
| 50 | INCLUDEPATH += $$WEBKITDIR/JavaScriptCore
|
|---|
| 51 | INCLUDEPATH += $$WEBKITDIR/JavaScriptCore/parser
|
|---|
| 52 | INCLUDEPATH += $$WEBKITDIR/JavaScriptCore/bytecompiler
|
|---|
| 53 | INCLUDEPATH += $$WEBKITDIR/JavaScriptCore/debugger
|
|---|
| 54 | INCLUDEPATH += $$WEBKITDIR/JavaScriptCore/runtime
|
|---|
| 55 | INCLUDEPATH += $$WEBKITDIR/JavaScriptCore/wtf
|
|---|
| 56 | INCLUDEPATH += $$WEBKITDIR/JavaScriptCore/unicode
|
|---|
| 57 | INCLUDEPATH += $$WEBKITDIR/JavaScriptCore/interpreter
|
|---|
| 58 | INCLUDEPATH += $$WEBKITDIR/JavaScriptCore/jit
|
|---|
| 59 | INCLUDEPATH += $$WEBKITDIR/JavaScriptCore/profiler
|
|---|
| 60 | INCLUDEPATH += $$WEBKITDIR/JavaScriptCore/wrec
|
|---|
| 61 | INCLUDEPATH += $$WEBKITDIR/JavaScriptCore/API
|
|---|
| 62 | INCLUDEPATH += $$WEBKITDIR/JavaScriptCore/bytecode
|
|---|
| 63 | INCLUDEPATH += $$WEBKITDIR/JavaScriptCore/assembler
|
|---|
| 64 | INCLUDEPATH += $$WEBKITDIR/JavaScriptCore/generated
|
|---|
| 65 |
|
|---|
| 66 | # This line copied from WebCore.pro
|
|---|
| 67 | DEFINES += WTF_USE_JAVASCRIPTCORE_BINDINGS=1 WTF_CHANGES=1
|
|---|
| 68 |
|
|---|
| 69 | DEFINES += NDEBUG
|
|---|
| 70 |
|
|---|
| 71 | solaris-g++:isEqual(QT_ARCH,sparc) {
|
|---|
| 72 | CONFIG -= separate_debug_info
|
|---|
| 73 | CONFIG += no_debug_info
|
|---|
| 74 | }
|
|---|
| 75 |
|
|---|
| 76 | # Avoid JSC C API functions being exported.
|
|---|
| 77 | DEFINES += JS_NO_EXPORT
|
|---|
| 78 |
|
|---|
| 79 | INCLUDEPATH += $$PWD
|
|---|
| 80 |
|
|---|
| 81 | include(script.pri)
|
|---|
| 82 |
|
|---|
| 83 | symbian {
|
|---|
| 84 | TARGET.UID3=0x2001B2E1
|
|---|
| 85 | }
|
|---|
| 86 |
|
|---|
| 87 | symbian {
|
|---|
| 88 | symbian-abld|symbian-sbsv2 {
|
|---|
| 89 | MMP_RULES += ALWAYS_BUILD_AS_ARM
|
|---|
| 90 | } else {
|
|---|
| 91 | QMAKE_CFLAGS -= --thumb
|
|---|
| 92 | QMAKE_CXXFLAGS -= --thumb
|
|---|
| 93 | }
|
|---|
| 94 | QMAKE_CXXFLAGS.ARMCC += -OTime -O3
|
|---|
| 95 | }
|
|---|
| 96 |
|
|---|
| 97 | # WebKit doesn't compile in C++0x mode
|
|---|
| 98 | *-g++*:QMAKE_CXXFLAGS -= -std=c++0x -std=gnu++0x
|
|---|
