source: trunk/src/plugins/phonon/mmf/mmf.pro@ 890

Last change on this file since 890 was 846, checked in by Dmitry A. Kuminov, 14 years ago

trunk: Merged in qt 4.7.2 sources from branches/vendor/nokia/qt.
  • Property svn:eol-style set to native
File size: 5.7 KB
Line 
1# MMF Phonon backend
2symbian {
3 QT += phonon
4 TARGET = phonon_mmf
5 PHONON_MMF_DIR = $$QT_SOURCE_TREE/src/3rdparty/phonon/mmf
6
7 # Uncomment the following line in order to use the CDrmPlayerUtility client
8 # API for audio playback, rather than CMdaAudioPlayerUtility.
9 #CONFIG += phonon_mmf_audio_drm
10
11 phonon_mmf_audio_drm {
12 LIBS += -lDrmAudioPlayUtility
13 DEFINES += QT_PHONON_MMF_AUDIO_DRM
14 } else {
15 LIBS += -lmediaclientaudio
16 }
17
18 # This is necessary because both epoc32/include and Phonon contain videoplayer.h.
19 # By making /epoc32/include the first SYSTEMINCLUDE, we ensure that
20 # '#include <videoplayer.h>' picks up the Symbian header, as intended.
21 PREPEND_INCLUDEPATH = $${EPOCROOT}epoc32/include
22
23 PREPEND_INCLUDEPATH += $$QT_SOURCE_TREE/src/3rdparty
24
25 INCLUDEPATH += $$MW_LAYER_SYSTEMINCLUDE
26
27 HEADERS += \
28 $$PHONON_MMF_DIR/abstractaudioeffect.h \
29 $$PHONON_MMF_DIR/abstractmediaplayer.h \
30 $$PHONON_MMF_DIR/abstractplayer.h \
31 $$PHONON_MMF_DIR/abstractvideooutput.h \
32 $$PHONON_MMF_DIR/abstractvideoplayer.h \
33 $$PHONON_MMF_DIR/audioequalizer.h \
34 $$PHONON_MMF_DIR/audiooutput.h \
35 $$PHONON_MMF_DIR/audioplayer.h \
36 $$PHONON_MMF_DIR/backend.h \
37 $$PHONON_MMF_DIR/bassboost.h \
38 $$PHONON_MMF_DIR/defs.h \
39 $$PHONON_MMF_DIR/dummyplayer.h \
40 $$PHONON_MMF_DIR/effectfactory.h \
41 $$PHONON_MMF_DIR/effectparameter.h \
42 $$PHONON_MMF_DIR/environmentalreverb.h \
43 $$PHONON_MMF_DIR/loudness.h \
44 $$PHONON_MMF_DIR/mediaobject.h \
45 $$PHONON_MMF_DIR/mmf_medianode.h \
46 $$PHONON_MMF_DIR/stereowidening.h \
47 $$PHONON_MMF_DIR/objectdump.h \
48 $$PHONON_MMF_DIR/objectdump_symbian.h \
49 $$PHONON_MMF_DIR/objecttree.h \
50 $$PHONON_MMF_DIR/utils.h \
51 $$PHONON_MMF_DIR/videowidget.h
52
53 SOURCES += \
54 $$PHONON_MMF_DIR/abstractaudioeffect.cpp \
55 $$PHONON_MMF_DIR/abstractmediaplayer.cpp \
56 $$PHONON_MMF_DIR/abstractplayer.cpp \
57 $$PHONON_MMF_DIR/audioequalizer.cpp \
58 $$PHONON_MMF_DIR/audiooutput.cpp \
59 $$PHONON_MMF_DIR/audioplayer.cpp \
60 $$PHONON_MMF_DIR/abstractvideooutput.cpp \
61 $$PHONON_MMF_DIR/abstractvideoplayer.cpp \
62 $$PHONON_MMF_DIR/backend.cpp \
63 $$PHONON_MMF_DIR/bassboost.cpp \
64 $$PHONON_MMF_DIR/dummyplayer.cpp \
65 $$PHONON_MMF_DIR/effectfactory.cpp \
66 $$PHONON_MMF_DIR/effectparameter.cpp \
67 $$PHONON_MMF_DIR/environmentalreverb.cpp \
68 $$PHONON_MMF_DIR/loudness.cpp \
69 $$PHONON_MMF_DIR/mediaobject.cpp \
70 $$PHONON_MMF_DIR/mmf_medianode.cpp \
71 $$PHONON_MMF_DIR/stereowidening.cpp \
72 $$PHONON_MMF_DIR/objectdump.cpp \
73 $$PHONON_MMF_DIR/objectdump_symbian.cpp \
74 $$PHONON_MMF_DIR/objecttree.cpp \
75 $$PHONON_MMF_DIR/utils.cpp \
76 $$PHONON_MMF_DIR/videowidget.cpp
77
78 symbian {
79 # Test for whether the build environment supports video rendering to graphics
80 # surfaces.
81 exists($${EPOCROOT}epoc32/include/platform/videoplayer2.h) {
82 HEADERS += \
83 $$PHONON_MMF_DIR/videooutput_surface.h \
84 $$PHONON_MMF_DIR/videoplayer_surface.h
85 SOURCES += \
86 $$PHONON_MMF_DIR/videooutput_surface.cpp \
87 $$PHONON_MMF_DIR/videoplayer_surface.cpp
88 DEFINES += PHONON_MMF_VIDEO_SURFACES
89 } else {
90 HEADERS += \
91 $$PHONON_MMF_DIR/ancestormovemonitor.h \
92 $$PHONON_MMF_DIR/videooutput_dsa.h \
93 $$PHONON_MMF_DIR/videoplayer_dsa.h
94 SOURCES += \
95 $$PHONON_MMF_DIR/ancestormovemonitor.cpp \
96 $$PHONON_MMF_DIR/videooutput_dsa.cpp \
97 $$PHONON_MMF_DIR/videoplayer_dsa.cpp \
98 }
99
100 # Test whether the build environment includes support for the Download Manager
101 # API, required for Progressive Download
102 exists($${EPOCROOT}epoc32/include/downloadmgrclient.h) | \
103 exists($${EPOCROOT}epoc32/include/mw/downloadmgrclient.h) {
104 HEADERS += $$PHONON_MMF_DIR/download.h
105 SOURCES += $$PHONON_MMF_DIR/download.cpp
106 LIBS += -lDownloadMgr
107 DEFINES += PHONON_MMF_PROGRESSIVE_DOWNLOAD
108 }
109 }
110
111 LIBS += -lcone
112 LIBS += -lws32
113
114 # This is only needed for debug builds, but is always linked against.
115 LIBS += -lhal
116
117 TARGET.CAPABILITY = all -tcb
118
119 LIBS += -lmediaclientvideo # For CVideoPlayerUtility
120 LIBS += -lcone # For CCoeEnv
121 LIBS += -lws32 # For RWindow
122 LIBS += -lefsrv # For file server
123 LIBS += -lapgrfx -lapmime # For recognizer
124 LIBS += -lmmfcontrollerframework # For CMMFMetaDataEntry
125 LIBS += -lmediaclientaudiostream # For CMdaAudioOutputStream
126
127 # These are for effects.
128 LIBS += -lAudioEqualizerEffect -lBassBoostEffect -lDistanceAttenuationEffect -lDopplerbase -lEffectBase -lEnvironmentalReverbEffect -lListenerDopplerEffect -lListenerLocationEffect -lListenerOrientationEffect -lLocationBase -lLoudnessEffect -lOrientationBase -lSourceDopplerEffect -lSourceLocationEffect -lSourceOrientationEffect -lStereoWideningEffect
129
130 # This is to allow IAP to be specified
131 LIBS += -lCommDb
132
133 # This is needed for having the .qtplugin file properly created on Symbian.
134 QTDIR_build:DESTDIR = $$QT_BUILD_TREE/plugins/phonon_backend
135
136 target.path = $$[QT_INSTALL_PLUGINS]/phonon_backend
137 INSTALLS += target
138
139 include(../../qpluginbase.pri)
140
141 TARGET.UID3=0x2001E629
142}
Note: See TracBrowser for help on using the repository browser.