source: trunk/src/opengl/opengl.pro@ 616

Last change on this file since 616 was 561, checked in by Dmitry A. Kuminov, 15 years ago

trunk: Merged in qt 4.6.1 sources.
File size: 4.3 KB
Line 
1TARGET = QtOpenGL
2QPRO_PWD = $$PWD
3QT = core gui
4DEFINES += QT_BUILD_OPENGL_LIB
5DEFINES += QT_NO_USING_NAMESPACE
6win32-msvc*|win32-icc:QMAKE_LFLAGS += /BASE:0x63000000
7solaris-cc*:QMAKE_CXXFLAGS_RELEASE -= -O2
8
9unix:QMAKE_PKGCONFIG_REQUIRES = QtCore QtGui
10
11include(../qbase.pri)
12
13!win32:!embedded:!mac:CONFIG += x11
14contains(QT_CONFIG, opengl):CONFIG += opengl
15contains(QT_CONFIG, opengles1):CONFIG += opengles1
16contains(QT_CONFIG, opengles1cl):CONFIG += opengles1cl
17contains(QT_CONFIG, opengles2):CONFIG += opengles2
18contains(QT_CONFIG, egl):CONFIG += egl
19
20HEADERS += qgl.h \
21 qgl_p.h \
22 qglcolormap.h \
23 qglpixelbuffer.h \
24 qglpixelbuffer_p.h \
25 qglframebufferobject.h \
26 qglframebufferobject_p.h \
27 qglextensions_p.h \
28 qglpaintdevice_p.h \
29
30
31SOURCES += qgl.cpp \
32 qglcolormap.cpp \
33 qglpixelbuffer.cpp \
34 qglframebufferobject.cpp \
35 qglextensions.cpp \
36 qglpaintdevice.cpp \
37
38
39!contains(QT_CONFIG, opengles2) {
40 HEADERS += qpaintengine_opengl_p.h
41 SOURCES += qpaintengine_opengl.cpp
42}
43
44!contains(QT_CONFIG, opengles1):!contains(QT_CONFIG, opengles1cl) {
45 HEADERS += qglshaderprogram.h \
46 qglpixmapfilter_p.h \
47 qgraphicsshadereffect_p.h \
48 qgraphicssystem_gl_p.h \
49 qwindowsurface_gl_p.h \
50 qpixmapdata_gl_p.h \
51 gl2paintengineex/qglgradientcache_p.h \
52 gl2paintengineex/qglengineshadermanager_p.h \
53 gl2paintengineex/qgl2pexvertexarray_p.h \
54 gl2paintengineex/qpaintengineex_opengl2_p.h \
55 gl2paintengineex/qglengineshadersource_p.h \
56 gl2paintengineex/qglcustomshaderstage_p.h \
57 gl2paintengineex/qtriangulatingstroker_p.h
58
59 SOURCES += qglshaderprogram.cpp \
60 qglpixmapfilter.cpp \
61 qgraphicsshadereffect.cpp \
62 qgraphicssystem_gl.cpp \
63 qwindowsurface_gl.cpp \
64 qpixmapdata_gl.cpp \
65 gl2paintengineex/qglgradientcache.cpp \
66 gl2paintengineex/qglengineshadermanager.cpp \
67 gl2paintengineex/qgl2pexvertexarray.cpp \
68 gl2paintengineex/qpaintengineex_opengl2.cpp \
69 gl2paintengineex/qglcustomshaderstage.cpp \
70 gl2paintengineex/qtriangulatingstroker.cpp
71
72}
73
74x11 {
75 contains(QT_CONFIG, opengles1)|contains(QT_CONFIG, opengles1cl)|contains(QT_CONFIG, opengles2) {
76 SOURCES += qgl_x11egl.cpp \
77 qglpixelbuffer_egl.cpp \
78 qgl_egl.cpp \
79 qpixmapdata_x11gl_egl.cpp \
80 qwindowsurface_x11gl.cpp
81
82 HEADERS += qgl_egl_p.h \
83 qpixmapdata_x11gl_p.h \
84 qwindowsurface_x11gl_p.h
85
86 } else {
87 SOURCES += qgl_x11.cpp \
88 qglpixelbuffer_x11.cpp
89 }
90
91 contains(QT_CONFIG, fontconfig) {
92 contains(QT_CONFIG, system-freetype) {
93 embedded:CONFIG += opentype
94 # pull in the proper freetype2 include directory
95 include($$QT_SOURCE_TREE/config.tests/unix/freetype/freetype.pri)
96 LIBS_PRIVATE += -lfreetype
97 } else {
98 ### Note: how does this compile with a non-system freetype?
99 # This probably does not compile
100 }
101 } else {
102 DEFINES *= QT_NO_FREETYPE
103 }
104
105 LIBS_PRIVATE += $$QMAKE_LIBS_DYNLOAD
106}
107
108mac {
109 OBJECTIVE_SOURCES += qgl_mac.mm \
110 qglpixelbuffer_mac.mm
111 LIBS_PRIVATE += -framework AppKit -framework Carbon
112}
113win32:!wince*: {
114 SOURCES += qgl_win.cpp \
115 qglpixelbuffer_win.cpp
116}
117wince*: {
118 SOURCES += qgl_wince.cpp \
119 qglpixelbuffer_egl.cpp \
120 qgl_egl.cpp
121
122 HEADERS += qgl_cl_p.h \
123 qgl_egl_p.h \
124}
125
126embedded {
127 SOURCES += qgl_qws.cpp \
128 qglpixelbuffer_egl.cpp \
129 qglscreen_qws.cpp \
130 qglwindowsurface_qws.cpp \
131 qgl_egl.cpp
132
133 HEADERS += qglscreen_qws.h \
134 qglwindowsurface_qws_p.h \
135 qgl_egl_p.h
136
137 contains(QT_CONFIG, fontconfig) {
138 include($$QT_SOURCE_TREE/config.tests/unix/freetype/freetype.pri)
139 } else {
140 DEFINES *= QT_NO_FREETYPE
141 }
142}
143
144INCLUDEPATH += ../3rdparty/harfbuzz/src
Note: See TracBrowser for help on using the repository browser.