source: trunk/src/gui/painting/painting.pri@ 781

Last change on this file since 781 was 706, checked in by Dmitry A. Kuminov, 16 years ago

gui: Implemented drawing widgets through Dive (see #101) and enabled it by default.
File size: 15.8 KB
Line 
1# Qt gui library, paint module
2
3HEADERS += \
4 painting/qbezier_p.h \
5 painting/qbrush.h \
6 painting/qcolor.h \
7 painting/qcolor_p.h \
8 painting/qcolormap.h \
9 painting/qdrawutil.h \
10 painting/qemulationpaintengine_p.h \
11 painting/qgraphicssystem_p.h \
12 painting/qmatrix.h \
13 painting/qmemrotate_p.h \
14 painting/qoutlinemapper_p.h \
15 painting/qpaintdevice.h \
16 painting/qpaintengine.h \
17 painting/qpaintengine_p.h \
18 painting/qpaintengine_alpha_p.h \
19 painting/qpaintengine_preview_p.h \
20 painting/qpaintengineex_p.h \
21 painting/qpainter.h \
22 painting/qpainter_p.h \
23 painting/qpainterpath.h \
24 painting/qpainterpath_p.h \
25 painting/qvectorpath_p.h \
26 painting/qpathclipper_p.h \
27 painting/qpdf_p.h \
28 painting/qpen.h \
29 painting/qpolygon.h \
30 painting/qpolygonclipper_p.h \
31 painting/qprintengine.h \
32 painting/qprintengine_pdf_p.h \
33 painting/qprintengine_ps_p.h \
34 painting/qprinter.h \
35 painting/qprinter_p.h \
36 painting/qprinterinfo.h \
37 painting/qrasterizer_p.h \
38 painting/qregion.h \
39 painting/qstroker_p.h \
40 painting/qstylepainter.h \
41 painting/qtessellator_p.h \
42 painting/qtextureglyphcache_p.h \
43 painting/qtransform.h \
44 painting/qwindowsurface_p.h \
45 painting/qwmatrix.h \
46 painting/qpaintbuffer_p.h
47
48
49SOURCES += \
50 painting/qbezier.cpp \
51 painting/qblendfunctions.cpp \
52 painting/qbrush.cpp \
53 painting/qcolor.cpp \
54 painting/qcolor_p.cpp \
55 painting/qcssutil.cpp \
56 painting/qdrawutil.cpp \
57 painting/qemulationpaintengine.cpp \
58 painting/qgraphicssystem.cpp \
59 painting/qmatrix.cpp \
60 painting/qmemrotate.cpp \
61 painting/qoutlinemapper.cpp \
62 painting/qpaintdevice.cpp \
63 painting/qpaintengine.cpp \
64 painting/qpaintengine_alpha.cpp \
65 painting/qpaintengine_preview.cpp \
66 painting/qpaintengineex.cpp \
67 painting/qpainter.cpp \
68 painting/qpainterpath.cpp \
69 painting/qpathclipper.cpp \
70 painting/qpdf.cpp \
71 painting/qpen.cpp \
72 painting/qpolygon.cpp \
73 painting/qprintengine_pdf.cpp \
74 painting/qprintengine_ps.cpp \
75 painting/qprinter.cpp \
76 painting/qrasterizer.cpp \
77 painting/qregion.cpp \
78 painting/qstroker.cpp \
79 painting/qstylepainter.cpp \
80 painting/qtessellator.cpp \
81 painting/qtextureglyphcache.cpp \
82 painting/qtransform.cpp \
83 painting/qwindowsurface.cpp \
84 painting/qpaintbuffer.cpp
85
86 SOURCES += \
87 painting/qpaintengine_raster.cpp \
88 painting/qdrawhelper.cpp \
89 painting/qimagescale.cpp \
90 painting/qgrayraster.c
91
92 HEADERS += \
93 painting/qpaintengine_raster_p.h \
94 painting/qrasterdefs_p.h \
95 painting/qgrayraster_p.h
96
97win32 {
98 HEADERS += painting/qprintengine_win_p.h
99
100 SOURCES += \
101 painting/qcolormap_win.cpp \
102 painting/qpaintdevice_win.cpp \
103 painting/qprintengine_win.cpp \
104 painting/qprinterinfo_win.cpp
105
106 !win32-borland:!wince*:LIBS += -lmsimg32
107}
108
109os2 {
110 SOURCES += \
111 painting/qcolormap_pm.cpp \
112 painting/qpaintdevice_pm.cpp \
113 painting/qprinterinfo_pm.cpp
114}
115
116embedded {
117 HEADERS += \
118 painting/qgraphicssystem_qws_p.h \
119
120 SOURCES += \
121 painting/qgraphicssystem_qws.cpp \
122
123} else {
124 HEADERS += \
125 painting/qgraphicssystem_raster_p.h \
126 painting/qgraphicssystemfactory_p.h \
127 painting/qgraphicssystemplugin_p.h \
128 painting/qwindowsurface_raster_p.h \
129
130 SOURCES += \
131 painting/qgraphicssystem_raster.cpp \
132 painting/qgraphicssystemfactory.cpp \
133 painting/qgraphicssystemplugin.cpp \
134 painting/qwindowsurface_raster.cpp \
135}
136
137unix:x11 {
138 HEADERS += \
139 painting/qpaintengine_x11_p.h
140
141 SOURCES += \
142 painting/qcolormap_x11.cpp \
143 painting/qpaintdevice_x11.cpp \
144 painting/qpaintengine_x11.cpp
145}
146
147!embedded:!x11:mac {
148 HEADERS += \
149 painting/qpaintengine_mac_p.h \
150 painting/qgraphicssystem_mac_p.h \
151 painting/qprintengine_mac_p.h
152
153 SOURCES += \
154 painting/qcolormap_mac.cpp \
155 painting/qpaintdevice_mac.cpp \
156 painting/qpaintengine_mac.cpp \
157 painting/qgraphicssystem_mac.cpp \
158 painting/qprinterinfo_mac.cpp
159 OBJECTIVE_SOURCES += \
160 painting/qprintengine_mac.mm \
161}
162
163unix:!mac:!symbian {
164 HEADERS += \
165 painting/qprinterinfo_unix_p.h
166 SOURCES += \
167 painting/qprinterinfo_unix.cpp
168}
169
170win32|os2|x11|mac|embedded|symbian {
171 SOURCES += painting/qbackingstore.cpp
172 HEADERS += painting/qbackingstore_p.h
173}
174
175embedded {
176 contains(QT_CONFIG,qtopia) {
177 DEFINES += QTOPIA_PRINTENGINE
178 HEADERS += painting/qprintengine_qws_p.h
179 SOURCES += painting/qprintengine_qws.cpp
180 }
181
182 SOURCES += \
183 painting/qcolormap_qws.cpp \
184 painting/qpaintdevice_qws.cpp
185}
186
187symbian {
188 SOURCES += \
189 painting/qpaintengine_s60.cpp \
190 painting/qregion_s60.cpp \
191 painting/qcolormap_s60.cpp
192
193 HEADERS += \
194 painting/qpaintengine_s60_p.h
195}
196
197x11|embedded|os2 {
198 contains(QT_CONFIG,qtopia) {
199 DEFINES += QT_NO_CUPS QT_NO_LPR
200 } else {
201 SOURCES += painting/qcups.cpp
202 HEADERS += painting/qcups_p.h
203 }
204 os2 {
205 INCLUDEPATH += $$CUPS_INCLUDEPATH
206 LIBS += $$CUPS_LIBS
207 }
208} else {
209 DEFINES += QT_NO_CUPS QT_NO_LPR
210}
211
212contains(QMAKE_MAC_XARCH, no) {
213 DEFINES += QT_NO_MAC_XARCH
214} else:if(mmx|3dnow|sse|sse2|iwmmxt) {
215 HEADERS += painting/qdrawhelper_x86_p.h \
216 painting/qdrawhelper_mmx_p.h \
217 painting/qdrawhelper_sse_p.h
218 mmx {
219 DEFINES += QT_HAVE_MMX
220 MMX_SOURCES += painting/qdrawhelper_mmx.cpp
221 }
222 3dnow {
223 DEFINES += QT_HAVE_3DNOW
224 MMX3DNOW_SOURCES += painting/qdrawhelper_mmx3dnow.cpp
225 sse {
226 SSE3DNOW_SOURCES += painting/qdrawhelper_sse3dnow.cpp
227 }
228 }
229 sse {
230 DEFINES += QT_HAVE_SSE
231 SSE_SOURCES += painting/qdrawhelper_sse.cpp
232
233 DEFINES += QT_HAVE_MMXEXT
234 }
235 sse2 {
236 DEFINES += QT_HAVE_SSE2
237 SSE2_SOURCES += painting/qdrawhelper_sse2.cpp
238 }
239 iwmmxt {
240 DEFINES += QT_HAVE_IWMMXT
241 IWMMXT_SOURCES += painting/qdrawhelper_iwmmxt.cpp
242 }
243
244 win32-g++|!win32:!*-icc* {
245 mmx {
246 os2:mmx_compiler.commands = $$QMAKE_RUN_CXX -Winline
247 else:mmx_compiler.commands = $$QMAKE_CXX -c -Winline
248
249 mac {
250 mmx_compiler.commands += -Xarch_i386 -mmmx
251 mmx_compiler.commands += -Xarch_x86_64 -mmmx
252 } else {
253 mmx_compiler.commands += -mmmx
254 }
255
256 os2 {
257 mmx_compiler.commands = $$replace(mmx_compiler.commands, \\$src, ${QMAKE_FILE_IN})
258 mmx_compiler.commands = $$replace(mmx_compiler.commands, \\$obj, ${QMAKE_FILE_OUT})
259 } else {
260 mmx_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
261 }
262 mmx_compiler.dependency_type = TYPE_C
263 mmx_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
264 mmx_compiler.input = MMX_SOURCES
265 mmx_compiler.variable_out = OBJECTS
266 mmx_compiler.name = compiling[mmx] ${QMAKE_FILE_IN}
267 silent:mmx_compiler.commands = @echo compiling[mmx] ${QMAKE_FILE_IN} && $$mmx_compiler.commands
268 QMAKE_EXTRA_COMPILERS += mmx_compiler
269 }
270 3dnow {
271 os2:mmx3dnow_compiler.commands = $$QMAKE_RUN_CXX -Winline
272 else:mmx3dnow_compiler.commands = $$QMAKE_CXX -c -Winline
273
274 mac {
275 mmx3dnow_compiler.commands += -Xarch_i386 -m3dnow -Xarch_i386 -mmmx
276 mmx3dnow_compiler.commands += -Xarch_x86_64 -m3dnow -Xarch_x86_64 -mmmx
277 } else {
278 mmx3dnow_compiler.commands += -m3dnow -mmmx
279 }
280
281 os2 {
282 mmx3dnow_compiler.commands = $$replace(mmx3dnow_compiler.commands, \\$src, ${QMAKE_FILE_IN})
283 mmx3dnow_compiler.commands = $$replace(mmx3dnow_compiler.commands, \\$obj, ${QMAKE_FILE_OUT})
284 } else {
285 mmx3dnow_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
286 }
287 mmx3dnow_compiler.dependency_type = TYPE_C
288 mmx3dnow_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
289 mmx3dnow_compiler.input = MMX3DNOW_SOURCES
290 mmx3dnow_compiler.variable_out = OBJECTS
291 mmx3dnow_compiler.name = compiling[mmx3dnow] ${QMAKE_FILE_IN}
292 silent:mmx3dnow_compiler.commands = @echo compiling[mmx3dnow] ${QMAKE_FILE_IN} && $$mmx3dnow_compiler.commands
293 QMAKE_EXTRA_COMPILERS += mmx3dnow_compiler
294 sse {
295 os2:sse3dnow_compiler.commands = $$QMAKE_RUN_CXX -Winline
296 else:sse3dnow_compiler.commands = $$QMAKE_CXX -c -Winline
297
298 mac {
299 sse3dnow_compiler.commands += -Xarch_i386 -m3dnow -Xarch_i386 -msse
300 sse3dnow_compiler.commands += -Xarch_x86_64 -m3dnow -Xarch_x86_64 -msse
301 } else {
302 sse3dnow_compiler.commands += -m3dnow -msse
303 }
304
305 os2 {
306 sse3dnow_compiler.commands = $$replace(sse3dnow_compiler.commands, \\$src, ${QMAKE_FILE_IN})
307 sse3dnow_compiler.commands = $$replace(sse3dnow_compiler.commands, \\$obj, ${QMAKE_FILE_OUT})
308 } else {
309 sse3dnow_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
310 }
311 sse3dnow_compiler.dependency_type = TYPE_C
312 sse3dnow_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
313 sse3dnow_compiler.input = SSE3DNOW_SOURCES
314 sse3dnow_compiler.variable_out = OBJECTS
315 sse3dnow_compiler.name = compiling[sse3dnow] ${QMAKE_FILE_IN}
316 silent:sse3dnow_compiler.commands = @echo compiling[sse3dnow] ${QMAKE_FILE_IN} && $$sse3dnow_compiler.commands
317 QMAKE_EXTRA_COMPILERS += sse3dnow_compiler
318 }
319 }
320 sse {
321 os2:sse_compiler.commands = $$QMAKE_RUN_CXX -Winline
322 else:sse_compiler.commands = $$QMAKE_CXX -c -Winline
323
324 mac {
325 sse_compiler.commands += -Xarch_i386 -msse
326 sse_compiler.commands += -Xarch_x86_64 -msse
327 } else {
328 sse_compiler.commands += -msse
329 }
330
331 os2 {
332 sse_compiler.commands = $$replace(sse_compiler.commands, \\$src, ${QMAKE_FILE_IN})
333 sse_compiler.commands = $$replace(sse_compiler.commands, \\$obj, ${QMAKE_FILE_OUT})
334 } else {
335 sse_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
336 }
337 sse_compiler.dependency_type = TYPE_C
338 sse_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
339 sse_compiler.input = SSE_SOURCES
340 sse_compiler.variable_out = OBJECTS
341 sse_compiler.name = compiling[sse] ${QMAKE_FILE_IN}
342 silent:sse_compiler.commands = @echo compiling[sse] ${QMAKE_FILE_IN} && $$sse_compiler.commands
343 QMAKE_EXTRA_COMPILERS += sse_compiler
344 }
345 sse2 {
346 os2:sse2_compiler.commands = $$QMAKE_RUN_CXX -Winline
347 else:sse2_compiler.commands = $$QMAKE_CXX -c -Winline
348
349 mac {
350 sse2_compiler.commands += -Xarch_i386 -msse2
351 sse2_compiler.commands += -Xarch_x86_64 -msse2
352 } else {
353 sse2_compiler.commands += -msse2
354 }
355
356 os2 {
357 sse2_compiler.commands = $$replace(sse2_compiler.commands, \\$src, ${QMAKE_FILE_IN})
358 sse2_compiler.commands = $$replace(sse2_compiler.commands, \\$obj, ${QMAKE_FILE_OUT})
359 } else {
360 sse2_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
361 }
362 sse2_compiler.dependency_type = TYPE_C
363 sse2_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
364 sse2_compiler.input = SSE2_SOURCES
365 sse2_compiler.variable_out = OBJECTS
366 sse2_compiler.name = compiling[sse2] ${QMAKE_FILE_IN}
367 silent:sse2_compiler.commands = @echo compiling[sse2] ${QMAKE_FILE_IN} && $$sse2_compiler.commands
368 QMAKE_EXTRA_COMPILERS += sse2_compiler
369 }
370 iwmmxt {
371 os2:iwmmxt_compiler.commands = $$QMAKE_RUN_CXX -Winline
372 else:iwmmxt_compiler.commands = $$QMAKE_CXX -c -Winline
373 iwmmxt_compiler.commands += -mcpu=iwmmxt
374 os2 {
375 iwmmxt_compiler.commands = $$replace(iwmmxt_compiler.commands, \\$src, ${QMAKE_FILE_IN})
376 iwmmxt_compiler.commands = $$replace(iwmmxt_compiler.commands, \\$obj, ${QMAKE_FILE_OUT})
377 } else {
378 iwmmxt_compiler.commands += $(CXXFLAGS) $(INCPATH) ${QMAKE_FILE_IN} -o ${QMAKE_FILE_OUT}
379 }
380 iwmmxt_compiler.dependency_type = TYPE_C
381 iwmmxt_compiler.output = ${QMAKE_VAR_OBJECTS_DIR}${QMAKE_FILE_BASE}$${first(QMAKE_EXT_OBJ)}
382 iwmmxt_compiler.input = IWMMXT_SOURCES
383 iwmmxt_compiler.variable_out = OBJECTS
384 iwmmxt_compiler.name = compiling[iwmmxt] ${QMAKE_FILE_IN}
385 silent:iwmmxt_compiler.commands = @echo compiling[iwmmxt] ${QMAKE_FILE_IN} && $$iwmmxt_compiler.commands
386 QMAKE_EXTRA_COMPILERS += iwmmxt_compiler
387 }
388 } else {
389 mmx: SOURCES += $$MMX_SOURCES
390 3dnow: SOURCES += $$MMX3DNOW_SOURCES
391 3dnow:sse: SOURCES += $$SSE3DNOW_SOURCES
392 sse: SOURCES += $$SSE_SOURCES
393 sse2: SOURCES += $$SSE2_SOURCES
394 iwmmxt: SOURCES += $$IWMMXT_SOURCES
395 }
396}
397
398x11 {
399 HEADERS += painting/qwindowsurface_x11_p.h
400 SOURCES += painting/qwindowsurface_x11.cpp
401}
402
403mac {
404 HEADERS += painting/qwindowsurface_mac_p.h
405 SOURCES += painting/qwindowsurface_mac.cpp
406}
407
408embedded {
409 HEADERS += painting/qwindowsurface_qws_p.h
410 SOURCES += painting/qwindowsurface_qws.cpp
411}
412
413os2 {
414 HEADERS += painting/qwindowsurface_pm_p.h
415 SOURCES += painting/qwindowsurface_pm.cpp
416}
417
418symbian {
419 HEADERS += painting/qwindowsurface_s60_p.h
420 SOURCES += painting/qwindowsurface_s60.cpp
421 armccIfdefBlock = \
422 "$${LITERAL_HASH}if defined(ARMV6)" \
423 "SOURCEPATH painting" \
424 "SOURCE qblendfunctions_armv6_rvct.s" \
425 "SOURCE qdrawhelper_armv6_rvct.s" \
426 "$${LITERAL_HASH}endif"
427
428 MMP_RULES += armccIfdefBlock
429 QMAKE_CXXFLAGS.ARMCC *= -O3
430}
431
432neon {
433 DEFINES += QT_HAVE_NEON
434 HEADERS += painting/qdrawhelper_neon_p.h
435 SOURCES += painting/qdrawhelper_neon.cpp
436 QMAKE_CXXFLAGS *= -mfpu=neon
437}
438
439contains(QT_CONFIG, zlib) {
440 INCLUDEPATH += ../3rdparty/zlib
441} else:!contains(QT_CONFIG, no-zlib) {
442 unix:LIBS_PRIVATE += -lz
443# win32:LIBS += libz.lib
444}
445
Note: See TracBrowser for help on using the repository browser.