source: trunk/mkspecs/features/os2/default_post.prf@ 298

!CONFIG(windows):!CONFIG(console) {
    CONFIG(release, debug|release):CONFIG(qt):contains(QT, gui) {
        CONFIG *= windows
    } else {
        CONFIG *= console
    }
}

# load the global default_post
load(default_post)

wlink:build_pass {
    # Neither WLINK nor EMXOMFLD allows us to specify the application type of
    # the .EXE on the command line. For this reason, we need an implicit .DEF
    # file which we create unless an explicit .DEF file is provided in .pro.
    contains(TEMPLATE, ".*app") {
        isEmpty(DEF_FILE) {
            DEF_FILE = $(OBJECTS_DIR)/$(TARGET).def

            make_apptype_def.target = $(DEF_FILE)
            make_apptype_def.depends = $(call q,$(MAKEFILE))
            windows {
                make_apptype_def.commands = @echo NAME $(QMAKE_TARGET) WINDOWAPI > $(DEF_FILE)
            } else {
                make_apptype_def.commands = @echo NAME $(QMAKE_TARGET) WINDOWCOMPAT > $(DEF_FILE)
            }
            QMAKE_EXTRA_TARGETS += make_apptype_def
            QMAKE_CLEAN += $(DEF_FILE)
        }
    }
}