source: branches/vendor/nokia/qt/current/src/src.pro@ 890

Last change on this file since 890 was 844, checked in by Dmitry A. Kuminov, 15 years ago

vendor: Imported qt-everywhere-opensource-src-4.7.2 from Nokia (excluding doc/html and doc/qch dirs generated from doc/src, and imports and templates dirs which are emtpy).
File size: 9.2 KB
Line 
1TEMPLATE = subdirs
2
3# this order is important
4unset(SRC_SUBDIRS)
5win32:SRC_SUBDIRS += src_winmain
6symbian:SRC_SUBDIRS += src_s60main
7SRC_SUBDIRS += src_corelib src_xml src_network src_sql src_testlib
8!symbian:contains(QT_CONFIG, dbus):SRC_SUBDIRS += src_dbus
9!contains(QT_CONFIG, no-gui): SRC_SUBDIRS += src_gui
10!wince*:!symbian:!vxworks:contains(QT_CONFIG, qt3support): SRC_SUBDIRS += src_qt3support
11
12!wince*:!symbian-abld:!symbian-sbsv2:include(tools/tools.pro)
13win32:SRC_SUBDIRS += src_activeqt
14
15contains(QT_CONFIG, opengl)|contains(QT_CONFIG, opengles1)|contains(QT_CONFIG, opengles2): SRC_SUBDIRS += src_opengl
16contains(QT_CONFIG, openvg): SRC_SUBDIRS += src_openvg
17contains(QT_CONFIG, xmlpatterns): SRC_SUBDIRS += src_xmlpatterns
18contains(QT_CONFIG, phonon): SRC_SUBDIRS += src_phonon
19contains(QT_CONFIG, multimedia): SRC_SUBDIRS += src_multimedia
20contains(QT_CONFIG, svg): SRC_SUBDIRS += src_svg
21contains(QT_CONFIG, script): SRC_SUBDIRS += src_script
22contains(QT_CONFIG, declarative): SRC_SUBDIRS += src_declarative
23contains(QT_CONFIG, webkit) {
24 exists($$QT_SOURCE_TREE/src/3rdparty/webkit/JavaScriptCore/JavaScriptCore.pro): SRC_SUBDIRS += src_javascriptcore
25 SRC_SUBDIRS += src_webkit
26}
27!contains(QT_CONFIG, no-gui):contains(QT_CONFIG, scripttools): SRC_SUBDIRS += src_scripttools
28SRC_SUBDIRS += src_plugins
29contains(QT_CONFIG, declarative): SRC_SUBDIRS += src_imports
30contains(QT_CONFIG, declarative):contains(QT_CONFIG, webkit): SRC_SUBDIRS += src_webkit_declarative
31
32# s60installs need to be at the end, because projects.pro does an ordered build,
33# and s60installs depends on all the others.
34symbian:SRC_SUBDIRS += src_s60installs
35
36src_s60main.subdir = $$QT_SOURCE_TREE/src/s60main
37src_s60main.target = sub-s60main
38src_s60installs.subdir = $$QT_SOURCE_TREE/src/s60installs
39src_s60installs.target = sub-s60installs
40src_winmain.subdir = $$QT_SOURCE_TREE/src/winmain
41src_winmain.target = sub-winmain
42src_corelib.subdir = $$QT_SOURCE_TREE/src/corelib
43src_corelib.target = sub-corelib
44src_xml.subdir = $$QT_SOURCE_TREE/src/xml
45src_xml.target = sub-xml
46src_xmlpatterns.subdir = $$QT_SOURCE_TREE/src/xmlpatterns
47src_xmlpatterns.target = sub-xmlpatterns
48src_dbus.subdir = $$QT_SOURCE_TREE/src/dbus
49src_dbus.target = sub-dbus
50src_gui.subdir = $$QT_SOURCE_TREE/src/gui
51src_gui.target = sub-gui
52src_sql.subdir = $$QT_SOURCE_TREE/src/sql
53src_sql.target = sub-sql
54src_network.subdir = $$QT_SOURCE_TREE/src/network
55src_network.target = sub-network
56src_svg.subdir = $$QT_SOURCE_TREE/src/svg
57src_svg.target = sub-svg
58src_script.subdir = $$QT_SOURCE_TREE/src/script
59src_script.target = sub-script
60src_scripttools.subdir = $$QT_SOURCE_TREE/src/scripttools
61src_scripttools.target = sub-scripttools
62src_opengl.subdir = $$QT_SOURCE_TREE/src/opengl
63src_opengl.target = sub-opengl
64src_openvg.subdir = $$QT_SOURCE_TREE/src/openvg
65src_openvg.target = sub-openvg
66src_qt3support.subdir = $$QT_SOURCE_TREE/src/qt3support
67src_qt3support.target = sub-qt3support
68src_phonon.subdir = $$QT_SOURCE_TREE/src/phonon
69src_phonon.target = sub-phonon
70src_multimedia.subdir = $$QT_SOURCE_TREE/src/multimedia
71src_multimedia.target = sub-multimedia
72src_activeqt.subdir = $$QT_SOURCE_TREE/src/activeqt
73src_activeqt.target = sub-activeqt
74src_plugins.subdir = $$QT_SOURCE_TREE/src/plugins
75src_plugins.target = sub-plugins
76src_imports.subdir = $$QT_SOURCE_TREE/src/imports
77src_imports.target = sub-imports
78src_testlib.subdir = $$QT_SOURCE_TREE/src/testlib
79src_testlib.target = sub-testlib
80src_javascriptcore.subdir = $$QT_SOURCE_TREE/src/3rdparty/webkit/JavaScriptCore
81src_javascriptcore.target = sub-javascriptcore
82src_webkit.subdir = $$QT_SOURCE_TREE/src/3rdparty/webkit/WebCore
83src_webkit.target = sub-webkit
84src_declarative.subdir = $$QT_SOURCE_TREE/src/declarative
85src_declarative.target = sub-declarative
86src_webkit_declarative.subdir = $$QT_SOURCE_TREE/src/3rdparty/webkit/WebKit/qt/declarative
87src_webkit_declarative.target = sub-webkitdeclarative
88
89#CONFIG += ordered
90!wince*:!ordered:!symbian-abld:!symbian-sbsv2 {
91 src_corelib.depends = src_tools_moc src_tools_rcc
92 src_gui.depends = src_corelib src_tools_uic
93 embedded: src_gui.depends += src_network
94 src_xml.depends = src_corelib
95 src_xmlpatterns.depends = src_corelib src_network
96 src_dbus.depends = src_corelib src_xml
97 src_svg.depends = src_corelib src_gui
98 src_script.depends = src_corelib
99 src_scripttools.depends = src_script src_gui src_network
100 src_network.depends = src_corelib
101 src_opengl.depends = src_gui
102 src_openvg.depends = src_gui
103 src_sql.depends = src_corelib
104 src_testlib.depends = src_corelib
105 src_qt3support.depends = src_gui src_xml src_network src_sql
106 src_tools_idc.depends = src_corelib # target defined in tools.pro
107 src_tools_uic3.depends = src_qt3support src_xml # target defined in tools.pro
108 src_phonon.depends = src_gui
109 src_multimedia.depends = src_gui
110 contains(QT_CONFIG, opengl):src_multimedia.depends += src_opengl
111 src_tools_activeqt.depends = src_tools_idc src_gui
112 src_declarative.depends = src_gui src_script src_network
113 src_plugins.depends = src_gui src_sql src_svg
114 contains(QT_CONFIG, multimedia):src_plugins.depends += src_multimedia
115 src_s60installs.depends = $$TOOLS_SUBDIRS $$SRC_SUBDIRS
116 src_s60installs.depends -= src_s60installs
117 src_imports.depends = src_gui src_declarative
118 contains(QT_CONFIG, webkit) {
119 src_webkit.depends = src_gui src_sql src_network
120 contains(QT_CONFIG, xmlpatterns): src_webkit.depends += src_xmlpatterns
121 src_imports.depends += src_webkit
122 exists($$QT_SOURCE_TREE/src/3rdparty/webkit/JavaScriptCore/JavaScriptCore.pro) {
123 src_webkit.depends += src_javascriptcore
124 src_javascriptcore.depends = src_corelib
125 }
126 }
127 contains(QT_CONFIG, qt3support): src_plugins.depends += src_qt3support
128 contains(QT_CONFIG, dbus):{
129 src_plugins.depends += src_dbus
130 src_phonon.depends += src_dbus
131 }
132 contains(QT_CONFIG, opengl)|contains(QT_CONFIG, opengles1)|contains(QT_CONFIG, opengles2) {
133 src_plugins.depends += src_opengl
134 src_declarative.depends += src_opengl
135 src_webkit.depends += src_opengl
136 }
137 contains(QT_CONFIG, xmlpatterns) {
138 src_declarative.depends += src_xmlpatterns
139 src_webkit.depends += src_xmlpatterns
140 }
141 contains(QT_CONFIG, svg) {
142 src_declarative.depends += src_svg
143 }
144 contains(QT_CONFIG, webkit) : contains(QT_CONFIG, declarative): src_webkit_declarative.depends = src_declarative src_webkit
145}
146
147
148# This creates a sub-src rule
149sub_src_target.CONFIG = recursive
150sub_src_target.recurse = $$TOOLS_SUBDIRS $$SRC_SUBDIRS
151sub_src_target.target = sub-src
152sub_src_target.recurse_target =
153QMAKE_EXTRA_TARGETS += sub_src_target
154
155# This gives us a top level debug/release
156for(subname, SRC_SUBDIRS) {
157 subdir = $$subname
158 !isEmpty($${subname}.subdir):subdir = $$eval($${subname}.subdir)
159 subpro = $$subdir/$${basename(subdir)}.pro
160 !exists($$subpro):next()
161 subtarget = $$replace(subdir, [^A-Za-z0-9], _)
162 reg_src = $$replace(QT_SOURCE_TREE, \\\\, \\\\)
163 subdir = $$replace(subdir, $$reg_src, $$QT_BUILD_TREE)
164 subdir = $$replace(subdir, /, $$QMAKE_DIR_SEP)
165 subdir = $$replace(subdir, \\\\, $$QMAKE_DIR_SEP)
166 SUB_TEMPLATE = $$list($$fromfile($$subpro, TEMPLATE))
167 !isEqual(subname, src_tools_bootstrap):if(isEqual($$SUB_TEMPLATE, lib) | isEqual($$SUB_TEMPLATE, subdirs) | isEqual(subname, src_tools_idc) | isEqual(subname, src_tools_uic3)):!separate_debug_info {
168 #debug
169 debug-$${subtarget}.depends = $${subdir}$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_DEBUG_TARGETS
170 debug-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) debug)
171 EXTRA_DEBUG_TARGETS += debug-$${subtarget}
172 QMAKE_EXTRA_TARGETS += debug-$${subtarget}
173 #release
174 release-$${subtarget}.depends = $${subdir}$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_RELEASE_TARGETS
175 release-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) release)
176 EXTRA_RELEASE_TARGETS += release-$${subtarget}
177 QMAKE_EXTRA_TARGETS += release-$${subtarget}
178 } else { #do not have a real debug target/release
179 #debug
180 debug-$${subtarget}.depends = $${subdir}$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_DEBUG_TARGETS
181 debug-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) first)
182 EXTRA_DEBUG_TARGETS += debug-$${subtarget}
183 QMAKE_EXTRA_TARGETS += debug-$${subtarget}
184 #release
185 release-$${subtarget}.depends = $${subdir}$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_RELEASE_TARGETS
186 release-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) first)
187 EXTRA_RELEASE_TARGETS += release-$${subtarget}
188 QMAKE_EXTRA_TARGETS += release-$${subtarget}
189 }
190}
191debug.depends = $$EXTRA_DEBUG_TARGETS
192release.depends = $$EXTRA_RELEASE_TARGETS
193QMAKE_EXTRA_TARGETS += debug release
194
195# This gives us a top-level runonphone target, which installs Qt and optionally QtWebKit.
196contains(CONFIG, run_on_phone) {
197 src_runonphone_target.target = runonphone
198 src_runonphone_target.commands = $(MAKE) -C $$QT_BUILD_TREE/src/s60installs runonphone
199 src_runonphone_target.depends = first
200 contains(QT_CONFIG, webkit) {
201 src_runonphone_target.commands += && $(MAKE) -C $$QT_BUILD_TREE/src/3rdparty/webkit/WebCore runonphone
202 }
203 QMAKE_EXTRA_TARGETS += src_runonphone_target
204}
205
206SUBDIRS += $$SRC_SUBDIRS
Note: See TracBrowser for help on using the repository browser.