source: branches/vendor/nokia/qt/4.6.1/src/src.pro@ 558

Last change on this file since 558 was 556, checked in by Dmitry A. Kuminov, 16 years ago

vendor: Merged in qt-everywhere-opensource-src-4.6.1 from Nokia.
File size: 7.5 KB
Line 
1TEMPLATE = subdirs
2
3# this order is important
4unset(SRC_SUBDIRS)
5win32:SRC_SUBDIRS += src_winmain
6wince*:{
7 SRC_SUBDIRS += src_corelib src_xml src_gui src_sql src_network src_testlib
8} else:symbian {
9 SRC_SUBDIRS += src_s60main src_corelib src_xml src_gui src_network src_sql src_testlib src_s60installs
10} else {
11 SRC_SUBDIRS += src_corelib src_xml src_network src_gui src_sql src_testlib
12 !vxworks:contains(QT_CONFIG, qt3support): SRC_SUBDIRS += src_qt3support
13 include(tools/tools.pro)
14 contains(QT_CONFIG, dbus):SRC_SUBDIRS += src_dbus
15}
16win32:SRC_SUBDIRS += src_activeqt
17
18contains(QT_CONFIG, opengl)|contains(QT_CONFIG, opengles1)|contains(QT_CONFIG, opengles2): SRC_SUBDIRS += src_opengl
19contains(QT_CONFIG, openvg): SRC_SUBDIRS += src_openvg
20contains(QT_CONFIG, xmlpatterns): SRC_SUBDIRS += src_xmlpatterns
21contains(QT_CONFIG, phonon): SRC_SUBDIRS += src_phonon
22contains(QT_CONFIG, multimedia): SRC_SUBDIRS += src_multimedia
23contains(QT_CONFIG, svg): SRC_SUBDIRS += src_svg
24contains(QT_CONFIG, webkit) {
25 #exists($$QT_SOURCE_TREE/src/3rdparty/webkit/JavaScriptCore/JavaScriptCore.pro): SRC_SUBDIRS += src_javascriptcore
26 SRC_SUBDIRS += src_webkit
27}
28contains(QT_CONFIG, script): SRC_SUBDIRS += src_script
29contains(QT_CONFIG, scripttools): SRC_SUBDIRS += src_scripttools
30contains(QT_CONFIG, declarative): SRC_SUBDIRS += src_declarative
31SRC_SUBDIRS += src_plugins
32
33src_s60main.subdir = $$QT_SOURCE_TREE/src/s60main
34src_s60main.target = sub-s60main
35src_s60installs.subdir = $$QT_SOURCE_TREE/src/s60installs
36src_s60installs.target = sub-s60installs
37src_winmain.subdir = $$QT_SOURCE_TREE/src/winmain
38src_winmain.target = sub-winmain
39src_corelib.subdir = $$QT_SOURCE_TREE/src/corelib
40src_corelib.target = sub-corelib
41src_xml.subdir = $$QT_SOURCE_TREE/src/xml
42src_xml.target = sub-xml
43src_xmlpatterns.subdir = $$QT_SOURCE_TREE/src/xmlpatterns
44src_xmlpatterns.target = sub-xmlpatterns
45src_dbus.subdir = $$QT_SOURCE_TREE/src/dbus
46src_dbus.target = sub-dbus
47src_gui.subdir = $$QT_SOURCE_TREE/src/gui
48src_gui.target = sub-gui
49src_sql.subdir = $$QT_SOURCE_TREE/src/sql
50src_sql.target = sub-sql
51src_network.subdir = $$QT_SOURCE_TREE/src/network
52src_network.target = sub-network
53src_svg.subdir = $$QT_SOURCE_TREE/src/svg
54src_svg.target = sub-svg
55src_script.subdir = $$QT_SOURCE_TREE/src/script
56src_script.target = sub-script
57src_scripttools.subdir = $$QT_SOURCE_TREE/src/scripttools
58src_scripttools.target = sub-scripttools
59src_opengl.subdir = $$QT_SOURCE_TREE/src/opengl
60src_opengl.target = sub-opengl
61src_openvg.subdir = $$QT_SOURCE_TREE/src/openvg
62src_openvg.target = sub-openvg
63src_qt3support.subdir = $$QT_SOURCE_TREE/src/qt3support
64src_qt3support.target = sub-qt3support
65src_phonon.subdir = $$QT_SOURCE_TREE/src/phonon
66src_phonon.target = sub-phonon
67src_multimedia.subdir = $$QT_SOURCE_TREE/src/multimedia
68src_multimedia.target = sub-multimedia
69src_activeqt.subdir = $$QT_SOURCE_TREE/src/activeqt
70src_activeqt.target = sub-activeqt
71src_plugins.subdir = $$QT_SOURCE_TREE/src/plugins
72src_plugins.target = sub-plugins
73src_testlib.subdir = $$QT_SOURCE_TREE/src/testlib
74src_testlib.target = sub-testlib
75src_javascriptcore.subdir = $$QT_SOURCE_TREE/src/3rdparty/webkit/JavaScriptCore
76src_javascriptcore.target = sub-javascriptcore
77src_webkit.subdir = $$QT_SOURCE_TREE/src/3rdparty/webkit/WebCore
78src_webkit.target = sub-webkit
79src_declarative.subdir = $$QT_SOURCE_TREE/src/declarative
80src_declarative.target = sub-declarative
81
82#CONFIG += ordered
83!wince*:!symbian:!ordered {
84 src_corelib.depends = src_tools_moc src_tools_rcc
85 src_gui.depends = src_corelib src_tools_uic
86 embedded: src_gui.depends += src_network
87 src_xml.depends = src_corelib
88 src_xmlpatterns.depends = src_corelib src_network
89 src_dbus.depends = src_corelib src_xml
90 src_svg.depends = src_xml src_gui
91 src_script.depends = src_corelib
92 src_scripttools.depends = src_script src_gui src_network
93 src_network.depends = src_corelib
94 src_opengl.depends = src_gui
95 src_openvg.depends = src_gui
96 src_sql.depends = src_corelib
97 src_testlib.depends = src_corelib
98 src_qt3support.depends = src_gui src_xml src_network src_sql
99 src_tools_idc.depends = src_corelib # target defined in tools.pro
100 src_tools_uic3.depends = src_qt3support src_xml # target defined in tools.pro
101 src_phonon.depends = src_gui
102 src_multimedia.depends = src_gui
103 src_tools_activeqt.depends = src_tools_idc src_gui
104 src_declarative.depends = src_xml src_gui src_script src_network src_svg
105 src_plugins.depends = src_gui src_sql src_svg
106 contains(QT_CONFIG, webkit) {
107 src_webkit.depends = src_gui src_sql src_network src_xml
108 contains(QT_CONFIG, phonon):src_webkit.depends += src_phonon
109 contains(QT_CONFIG, declarative):src_declarative.depends += src_webkit
110 #exists($$QT_SOURCE_TREE/src/3rdparty/webkit/JavaScriptCore/JavaScriptCore.pro): src_webkit.depends += src_javascriptcore
111 }
112 contains(QT_CONFIG, qt3support): src_plugins.depends += src_qt3support
113 contains(QT_CONFIG, dbus):{
114 src_plugins.depends += src_dbus
115 src_phonon.depends += src_dbus
116 }
117 contains(QT_CONFIG, opengl)|contains(QT_CONFIG, opengles1)|contains(QT_CONFIG, opengles2): src_plugins.depends += src_opengl
118}
119
120!symbian {
121# This creates a sub-src rule
122sub_src_target.CONFIG = recursive
123sub_src_target.recurse = $$TOOLS_SUBDIRS $$SRC_SUBDIRS
124sub_src_target.target = sub-src
125sub_src_target.recurse_target =
126QMAKE_EXTRA_TARGETS += sub_src_target
127
128# This gives us a top level debug/release
129for(subname, SRC_SUBDIRS) {
130 subdir = $$subname
131 !isEmpty($${subname}.subdir):subdir = $$eval($${subname}.subdir)
132 subpro = $$subdir/$${basename(subdir)}.pro
133 !exists($$subpro):next()
134 subtarget = $$replace(subdir, [^A-Za-z0-9], _)
135 reg_src = $$replace(QT_SOURCE_TREE, \\\\, \\\\)
136 subdir = $$replace(subdir, $$reg_src, $$QT_BUILD_TREE)
137 subdir = $$replace(subdir, /, $$QMAKE_DIR_SEP)
138 subdir = $$replace(subdir, \\\\, $$QMAKE_DIR_SEP)
139 SUB_TEMPLATE = $$list($$fromfile($$subpro, TEMPLATE))
140 !isEqual(subname, src_tools_bootstrap):if(isEqual($$SUB_TEMPLATE, lib) | isEqual($$SUB_TEMPLATE, subdirs) | isEqual(subname, src_tools_idc) | isEqual(subname, src_tools_uic3)):!separate_debug_info {
141 #debug
142 eval(debug-$${subtarget}.depends = $${subdir}\$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_DEBUG_TARGETS)
143 eval(debug-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) debug))
144 EXTRA_DEBUG_TARGETS += debug-$${subtarget}
145 QMAKE_EXTRA_TARGETS += debug-$${subtarget}
146 #release
147 eval(release-$${subtarget}.depends = $${subdir}\$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_RELEASE_TARGETS)
148 eval(release-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) release))
149 EXTRA_RELEASE_TARGETS += release-$${subtarget}
150 QMAKE_EXTRA_TARGETS += release-$${subtarget}
151 } else { #do not have a real debug target/release
152 #debug
153 eval(debug-$${subtarget}.depends = $${subdir}\$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_DEBUG_TARGETS)
154 eval(debug-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) first))
155 EXTRA_DEBUG_TARGETS += debug-$${subtarget}
156 QMAKE_EXTRA_TARGETS += debug-$${subtarget}
157 #release
158 eval(release-$${subtarget}.depends = $${subdir}\$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_RELEASE_TARGETS)
159 eval(release-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) first))
160 EXTRA_RELEASE_TARGETS += release-$${subtarget}
161 QMAKE_EXTRA_TARGETS += release-$${subtarget}
162 }
163}
164debug.depends = $$EXTRA_DEBUG_TARGETS
165release.depends = $$EXTRA_RELEASE_TARGETS
166QMAKE_EXTRA_TARGETS += debug release
167}
168
169SUBDIRS += $$SRC_SUBDIRS
Note: See TracBrowser for help on using the repository browser.