source: branches/libc-0.6/src/gcc/libjava/testsuite/libjava.mauve/mauve.exp

# Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003 Free Software Foundation.
# Written by Tom Tromey <[email protected]>.
# Incorporate Mauve into libjava's DejaGNU test suite framework.

# FIXME: should be able to compile from source as well as from .class.


# Compute list of files to compile.  Returns list of all files
# representing classes that must be tested.  Result parameter `uses'
# maps source file names onto list of objects required for link.
proc mauve_compute_uses {aName} {
  upvar $aName uses
  global env runtests

  set fd [open classes r]
  set line [read $fd]
  close $fd

  foreach item [split $line] {
    if {$item == ""} then {
      continue
    }
    set item [join [split $item .] /].java

    # User might have specified "mauve.exp=something.java".
    if {! [runtest_file_p $runtests $item]} {
      continue
    }

    # Look for Uses line in source file.
    set fd [open $env(MAUVEDIR)/$item r]
    set ufiles [list $item]
    set dir [file dirname $item]
    while {[gets $fd sline] != -1} {
      if {[regsub -- {^// Uses:} $sline {} sline]} then {
        foreach uf [split $sline] {
          if {$uf != ""} then {
            lappend ufiles $dir/$uf
          }
        }
      }
    }
    close $fd

    set uses($item) {}
    foreach file $ufiles {
      set file [file rootname $file].o
      lappend uses($item) $file
      # Now add all inner classes
      foreach inner [glob -nocomplain [file rootname $file]$*.class] {
        # Prevent excessive escaping by replacing $ with a ^ in the .o name
        set inner [file rootname $inner].o
        regsub -all "\\$" $inner "\^" inner
        lappend uses($item) $inner
      }
    }
  }

  return [lsort [array names uses]]
}

# Find Mauve sources.  At end, env(MAUVEDIR) points to sources.
# Returns 0 if sources not found, 1 otherwise.
proc find_mauve_sources {} {
  global env srcdir

  if {[info exists env(MAUVEDIR)]} {
    return 1
  } elseif {[file isdirectory $srcdir/libjava.mauve/mauve]} {
    set env(MAUVEDIR) $srcdir/libjava.mauve/mauve
    return 1
  }

  return 0
}

# Run all the Mauve tests.  Return 1 on success, 0 on any failure.  If
# the tests are skipped, that is treated like success.
proc test_mauve {} {
  global srcdir objdir subdir env